Удаление объекта после проигрывания его анимации

[lesnoj]

Подскажите, как удалить объект и слушатель после проигрывания его анимации?

package src {
 
	import flash.display.MovieClip;
	import flash.display.DisplayObject;
	import flash.events.MouseEvent;
	import flash.events.Event;
 
	public class Main extends MovieClip {
 
		private var anyKey:AnyKey = new AnyKey();
 
		public function Main() {
			anyKey.x = 0;
			anyKey.y = 0;
			addChild(anyKey);
			anyKey.addEventListener(MouseEvent.CLICK, anyKeyClick);
		}
 
		public function anyKeyClick(event:MouseEvent):void {
			anyKey.gotoAndPlay("movie");
		}
 
	}
}

[nubideus]

http://help.adobe.com/ru_RU/FlashPla...l#currentFrame

http://help.adobe.com/ru_RU/FlashPla...ml#totalFrames

и событие enterFrame

[lesnoj]

Подойдут ли предложенные свойства, если анимация не одна? Возможно сочетание enterFrame и isPlaying?
Прошу так подробно разжевать потому что на данном этапе изучения AS3.0 даже простой пример может отнять кучу времени. Хотелось бы наверняка определиться со способом прежде чем приступить к экспериментам.

Временно пытаюсь решить задачу, прописав удаление в последнем кадре анимации.

this.parent.removeChild(this); // работает исправно

Подскажите как заставить работать следующие две строки:

anyKey.removeEventListener(MouseEvent.CLICK, anyKeyClick);
anyKey = null;

[caseyryan]

прописав удаление в последнем кадре анимации.

Лучше вместо этого в последнем кадре прописать это

import flash.events.Event;
dispatchEvent(new Event(Event.COMPLETE));

А в коде класса сделать так:

package src {
 
	import flash.display.MovieClip;
	import flash.display.DisplayObject;
	import flash.events.MouseEvent;
	import flash.events.Event;
 
	public class Main extends MovieClip {
 
		private var anyKey:AnyKey = new AnyKey();
 
		public function Main() {
			anyKey.x = 0;
			anyKey.y = 0;
			addChild(anyKey);
			anyKey.addEventListener(MouseEvent.CLICK, anyKeyClick);
			anyKey.addEventListener(Event.COMPLETE, onComplete);
		}
 
		public function onComplete(event:Event):void {
			anyKey.removeEventListener(MouseEvent.CLICK, anyKeyClick);
			anyKey.removeEventListener(Event.COMPLETE, onComplete);
			if (anyKey.parent) anyKey.parent.removeChild(anyKey);
			anyKey = null;
		}
 		public function anyKeyClick(event:MouseEvent):void {
			anyKey.gotoAndPlay("movie");
		}
	}
}