Пользовательские события

[web5talker]

Здравствуйте уважаемые форумчане!
Так и не разобрался, как "ловить" такое событие.

Добавлено через 30 секунд
Слушать*

[BornTOFree]

addEventListener(MyEvent.SOME_TYPE, myFunction);
 
private function myFunction(e:MyEvent):void {
 
}

[web5talker]

Код source.api.MethodEvent:

package source.api
{
 
	import flash.events.Event;
 
	public class MethodEvent extends Event
	{
		public static const LOAD_COMPLETE:String = "loadComplete";
		public var data:Object = null;
 
		public function MethodEvent(type:String, bubbles:Boolean=false, cancelable:Boolean=false)
		{
			super(type, bubbles, cancelable);
		}
 
		public override function clone():Event
		{
			var event:MethodEvent = new MethodEvent(type,bubbles,cancelable);
			event.data = this.data;
			return event;
		}
 
		public override function toString():String
		{
			return formatToString("MyEvent", "type", "bubbles", "cancelable", "eventPhase");
		}
	}
}

Код source.api.Users:

package source.api
{
	import flash.net.*;
	import flash.events.*;
	import source.parser.json.JSON;
	import source.api.MethodEvent;
	import flash.events.EventDispatcher;
 
	public class Users extends EventDispatcher
	{
		private static var uid:String = Main.uid;
		private static var accessToken:String = Main.accessToken;
 
		public function Users()
		{
 
		}
 
		public function Get()
		{
			var urlLoader:URLLoader = new URLLoader();
			var request = new URLRequest('https://api.vk.com/method/users.get?uids=' + uid + '&fields=online,photo_50,status');
			urlLoader.load(request);
			urlLoader.addEventListener(Event.COMPLETE,completeHandlerUrlLoader);
			function completeHandlerUrlLoader(e:Event):void
			{
				var event:MethodEvent = new MethodEvent(MethodEvent.LOAD_COMPLETE);
				event.data = JSON.decode(urlLoader.data).response[0];
				dispatchEvent(event);
			}
		}
	}
}

Код Main:

package 
{
 
	import flash.display.MovieClip;
	import flash.events.*;
	import flash.display.Stage;
	import flash.events.EventDispatcher;
 
	import source.api.Users;
 
	public class Main extends MovieClip
	{
		public static var mc:Stage;
		public static var accessToken:String;
		public static var uid:String;
 
		public function Main()
		{
			mc = stage;
			accessToken = '54gcb3cac27c01ebf7rt456u456yj36c59e52d61106aef5a6fd43275ca754e76cb659d2a0';
			uid = '161013291';
			var users:Users = new Users();
			users.addEventListener(MethodEvent.LOAD_COMPLETE,loadedHandler);
			users.Get();
			function loadedHandler(e:Event)
			{
 
			}
		}
	}
}

Может чего-то не так понял.
Выводит:

C:\Users\Жека\Documents\client vk\Main.as, Line 23	1120: Access of undefined property MethodEvent.

[Wolsh]

Ну так а где импорт MethodEvent в Мейне?

[web5talker]

Сообщение от Wolsh

Ну так а где импорт MethodEvent в Мейне?

Импортнул, теперь выдает при трейсе:

trace(e.data);

=

C:\Users\Жека\Documents\client vk\Main.as, Line 28	1119: Access of possibly undefined property data through a reference with static type flash.events:Event.

package source.api
{
 
	import flash.events.Event;
 
	public class MethodEvent extends Event
	{
		public static const LOAD_COMPLETE:String = "loadComplete";
		public var data:Object = null;
 
		public function MethodEvent(type:String, bubbles:Boolean=false, cancelable:Boolean=false)
		{
			super(type, bubbles, cancelable);
 
		}
 
		public override function clone():Event
		{
			var event:MethodEvent = new MethodEvent(type,bubbles,cancelable);
			event.data = this.data;
			return event;
		}
 
		public override function toString():String
		{
			return formatToString("MethodEvent", "type", "bubbles", "cancelable", "eventPhase");
		}
 
	}
}

package source.api
{
	import flash.net.*;
	import flash.events.*;
	import source.parser.json.JSON;
	import source.api.MethodEvent;
	import flash.events.EventDispatcher;
 
	public class Users extends EventDispatcher
	{
		private static var uid:String = Main.uid;
		private static var accessToken:String = Main.accessToken;
 
		public function Users()
		{
 
		}
 
		public function Get()
		{
			var urlLoader:URLLoader = new URLLoader();
			var request = new URLRequest('https://api.vk.com/method/users.get?uids=' + uid + '&fields=online,photo_50,status');
			urlLoader.load(request);
			urlLoader.addEventListener(Event.COMPLETE,completeHandlerUrlLoader);
			function completeHandlerUrlLoader(e:Event):void
			{
				var event:MethodEvent = new MethodEvent(MethodEvent.LOAD_COMPLETE);
				event.data = JSON.decode(urlLoader.data).response[0];
				dispatchEvent(event);
			}
		}
	}
}

package 
{
 
	import flash.display.MovieClip;
	import flash.events.*;
	import flash.display.Stage;
	import flash.events.EventDispatcher;
 
	import source.api.Users;
	import source.api.MethodEvent;
 
	public class Main extends MovieClip
	{
		public static var mc:Stage;
		public static var accessToken:String;
		public static var uid:String;
 
		public function Main()
		{
			mc = stage;
			accessToken = '54gcb3cac27c01*b3eb04385ca36c59e52d61106aef5a6fd43275ca754e76cb659d2a0';
			uid = '161013291';
			var users:Users = new Users();
			users.addEventListener(MethodEvent.LOAD_COMPLETE,loadedHandler);
			users.Get();
			function loadedHandler(e:Event)
			{
				trace(e.data);
			}
		}
	}
}

[ChuwY]

function loadedHandler(e:Event)

>

function loadedHandler(e:MethodEvent):void

[web5talker]

Сообщение от ChuwY

function loadedHandler(e:Event)

>

function loadedHandler(e:MethodEvent):void

Спасибо большое! Теперь все ок