Утечка памяти

[Lascc]

Здравствуйте, подскажите что я делаю не правильно. Класс обращается за данными каждые 10 секунд. При какдом запросе приложение все больше и больше памяти "съедает" (смотрю через flash.system.System totalMemory). Как грамотно освободиться от утечки?

public class NameClass
	{
		private var variables:URLVariables;
		private var urlRequest:URLRequest;
		private var loader:URLLoader;
 
		private var timer:Timer  = new Timer(10000, 0);
 
		private var error:String;
 
		public function NameClass() 
		{
			timer.addEventListener(TimerEvent.TIMER, request);
			timer.start();
		}
 
		public function stop():void {
			timer.stop();
		}
		public function start():void {
			timer.start();
		}
 
		public function get error1():String {
			return error;
		}
		private function request(e:TimerEvent):void {
			variables = new URLVariables();
			variables.md5 = MD5.hash("SomeString");
                                  variables.data = "data";
 
			urlRequest = new URLRequest("http://192.168.10.50/test.php");
			urlRequest.data = variables;
			urlRequest.method = URLRequestMethod.POST
 
			loader = new URLLoader();
 
			loader.addEventListener(Event.COMPLETE, update);
			loader.addEventListener(IOErrorEvent.IO_ERROR, io_error);
 
			try {
				loader.load(urlRequest);
			}
			catch (error:Error) {
				loader.removeEventListener(Event.COMPLETE, update);
				loader.removeEventListener(IOErrorEvent.IO_ERROR, io_error);
			}
		}
 
		private function update(e:Event):void {
			loader.removeEventListener(Event.COMPLETE, update);
			loader.removeEventListener(IOErrorEvent.IO_ERROR, io_error);
			//Обработка
		}
 
		private function io_error(e:IOErrorEvent):void {
			e.currentTarget.removeEventListener(Event.COMPLETE, update);
			e.currentTarget.removeEventListener(IOErrorEvent.IO_ERROR, io_error);
			error = "Ошибка I/O";
			this.stop();		
		}
	}

[expl]

Попробуйте после завершения каждой загрузки и отписки от слушателей вызывать

System.gc();//Работает только в дебажной версии флешплеера

1. Если память перестала расти - значит утечки нет - просто GC не торопиться ее чистить, т.к. её хватает.
Варианты действий:
- забить, если не вызвает проблем - когда память потребуется или еще какие условия свершатся - все будет очищено;
- не создавать работы для GC - сделать пул создаваемых объектов.

2. Если память расти не перестала - ищем дальше

При поверхностном обзоре кода - не нашел более одного объекта, способного одновременно застрять в памяти.

Еще не ясно, что происходит в "//Обработка" - может там загруженный объект застревает где-то в глубине приложения.

[Lascc]

После System.gc(); память перестала расти. Пожете подсказать на счет:

не создавать работы для GC - сделать пул создаваемых объектов.

Как это сделать? Где посмотреть примеры кода?

[random13]

Сообщение от Lascc

После System.gc(); память перестала расти. Пожете подсказать на счет:

Как это сделать? Где посмотреть примеры кода?

http://ru.wikipedia.org/wiki/%D0%9E%...BF%D1%83%D0%BB

тут объяснение

[Lascc]

random13, Спасибо, но это я и сам нашел. Хотелось бы пример на AS3.

[leofit]

Если Вы уверены, что запрос длится менее 10 сек, что Вам мешает эти строки вынести в конструктор и создавать только один раз?

			variables = new URLVariables();
			variables.md5 = MD5.hash("SomeString");
                                  variables.data = "data";
 
			urlRequest = new URLRequest("http://192.168.10.50/test.php");
			urlRequest.data = variables;
			urlRequest.method = URLRequestMethod.POST
 
			loader = new URLLoader();

Даже вот так если по хорошему

 
public class NameClass
	{
		private var variables:URLVariables;
		private var urlRequest:URLRequest;
		private var loader:URLLoader;
 
		private var timer:Timer  = new Timer(10000, 0);
 
		private var error:String;
 
		public function NameClass() 
		{
 
                        variables = new URLVariables();
			variables.md5 = MD5.hash("SomeString");
                        variables.data = "data";
 
			urlRequest = new URLRequest("http://192.168.10.50/test.php");
			urlRequest.data = variables;
			urlRequest.method = URLRequestMethod.POST
 
			loader = new URLLoader();
 
			loader.addEventListener(Event.COMPLETE, update);
			loader.addEventListener(IOErrorEvent.IO_ERROR, io_error);
 
                        timer.addEventListener(TimerEvent.TIMER, request);
			timer.start();
 
		}
 
		public function stop():void {
			timer.stop();
		}
		public function start():void {
			timer.start();
		}
 
		public function get error1():String {
			return error;
		}
		private function request(e:TimerEvent):void {
 
 
			try {
				loader.load(urlRequest);
			}
			catch (error:Error) {
				//loader.removeEventListener(Event.COMPLETE, update);
				//loader.removeEventListener(IOErrorEvent.IO_ERROR, io_error);
			}
		}
 
		private function update(e:Event):void {
			//loader.removeEventListener(Event.COMPLETE, update);
			//loader.removeEventListener(IOErrorEvent.IO_ERROR, io_error);
			//Обработка
		}
 
		private function io_error(e:IOErrorEvent):void {
			//e.currentTarget.removeEventListener(Event.COMPLETE, update);
			//e.currentTarget.removeEventListener(IOErrorEvent.IO_ERROR, io_error);
			error = "Ошибка I/O";
			this.stop();		
		}
	}

[Obi]

Попробуйте на всякий случай использовать useWeakReference = true

P.S.: Не помню точно, но по-моему не должно возникнуть никаких проблем с использованием объекта loader повторно, без создания нового экземпляра.

[random13]

Сообщение от Obi

Попробуйте на всякий случай использовать useWeakReference = true

P.S.: Не помню точно, но по-моему не должно возникнуть никаких проблем с использованием объекта loader повторно, без создания нового экземпляра.

не лучшая практика

[Psycho Tiger]

Сообщение от random13

не лучшая практика

Почему?

[random13]

Сообщение от Psycho Tiger

Почему?

а что хорошего в слабых ссылках, на сколько я знаю лучше все предварительно подчистить за собой чтоб объект удалился