Ошибка friends.getAppUsers

[ivaniyses]

Наверное всех замучил этим friends.getAppUsers)))
Вот, посмотрите, что не так?(Не выводит не фотки не имена)
При этом приложение включено и доступно всем и установили его 20 человек.

import vk.APIConnection;
import vk.events.*;
import flash.text.TextField;
 
var flashVars:Object = stage.loaderInfo.parameters as Object;
var VK:APIConnection = new APIConnection(flashVars);
 
VK.api('friends.getAppUsers', {}, LoadFriends);
 
function LoadFriends(response:Object):void
{
	for(var i:uint = 0; i < response.length; i++)
	{
		var photo:Loader = new Loader();
		photo.x = 120 * i + 10;
		photo.y = 315;
 
		var photoRequest:URLRequest = new URLRequest(response[i]["photo"]);
 
		photo.load(photoRequest);
		addChild(photo);
 
		var tf:TextField = new TextField();
		tf.x = 120 * i + 7;
		tf.y = 365 + photo.width;;
		tf.text = response[i]["first_name"];
		tf.width = 150;
		addChild(tf);
	}
}

[FlasherEgor]

А что за приложение, если не секрет, можно посмотреть?
(прошу прощения за оффтоп)

[ivaniyses]

Сообщение от FlasherEgor

А что за приложение, если не секрет, можно посмотреть?
(прошу прощения за оффтоп)

Эмм, это просто тестовое приложение без всего.
Давайте по теме

[alexandrratush]

В методе VK.api вторым параметром должна стоять функция, которая обрабатывает возвращаемый результат. У вас же там ничего нету.

[ivaniyses]

Сообщение от alexandrratush

В методе VK.api вторым параметром должна стоять функция, которая обрабатывает возвращаемый результат. У вас же там ничего нету.

Можете исправить, голова совсем не варит))
Спасибо)

[alexandrratush]

А что сложного в этом?

VK.api('friends.getAppUsers', LoadFriends, null);

[ivaniyses]

Сообщение от alexandrratush

А что сложного в этом?

VK.api('friends.getAppUsers', LoadFriends, null);

И при этом не выводит
Весь день потратил, не понимаю, в чём же дело?

Добавлено через 7 минут
И так пробовал...

VK.api('friends.getAppUsers', {fields:'photo, first_name'}, LoadFriends);

[alexandrratush]

Стоп, все верно у вас было написано. Извиняюсь, что-то сам запутался.

[ivaniyses]

Сообщение от alexandrratush

Стоп, все верно у вас было написано. Извиняюсь, что-то сам запутался.

Так в чём же дело?
P/S: Если есть исходник, киньте пожалуйста

[alexandrratush]

Вот не поленился, набросал класс:

package  {
 
	import flash.display.MovieClip;
	import vk.APIConnection;
	import flash.net.URLRequest;
	import flash.display.Loader;
	import flash.text.TextField;
 
 
	public class Main extends MovieClip {
 
		private var VK:APIConnection;
		private var _appUsers:Object;
		private var _friends:Object;
 
 
		public function Main() {
			var flashVars:Object = stage.loaderInfo.parameters as Object;
 
			// Инициализация и загрузка всех друзей 
			VK = new APIConnection(flashVars);
			VK.api('friends.get', {fields:'first_name,last_name,photo_200_orig'}, loadFriends, onError);
		}
 
		private function loadFriends(response:Object):void {
			_friends = response;
 
			// Загрузка всех айди друзей, которые установили приложение
			VK.api('friends.getAppUsers', {}, loadAppFriends, onError);
		}
 
		private function loadAppFriends(response:Object):void {
			_appUsers = response;
 
			searchAppUsersData();
		}
 
		// Разбираем наши полученные объекты
		private function searchAppUsersData():void {
			var i:String;
			var i1:String;
			var idApp:String;
 
			// Поиск по всем айди наших друзей, установив. приложен.
			for (i in _appUsers) {
				idApp = _appUsers[i];
 
				// Поиск по конкретной айди
				for (i1 in _friends) {
 
					// Если найдена, то перезаписываем данные про друга
					if (_friends[i1].uid == idApp)
						_appUsers[i] = _friends[i1];
				}
			}
 
			//На выходе имеем _appUsers, в котором данные про нашых друзей {first_name,last_name,photo_200_orig}. Дальше нужно работать с ним.
		}
 
		// если произошла ошибка
        private function onError(data:Object):void {
            //
        }
 
	}
 
}

В вашем случае проблема была в том, что вы выбрали только айди друзей (в которых нет полей "photo" и т.д.), которые установили приложение. Вам же нужно еще и расширенную информацию о них. Это нужно делать отдельным запросом. После этого мы выбираем данные про друзей по айдишкам, которые нас интересуют.