статик конструктор

[undefined]

Имеется класс А, который активно работает с тригонометрией.В целях оптимизации думаю вынести все значения тригонометрических функций в precalculated табличку.Хранить её думаю в статичном поле того же класса.Возникает вопрос где можно заполнять эту таблицу?Можно конечно это делать один раз при создании экземляра A.Но как-то оно кажется кривым т.к. табличка в будущем может понадобится другим классам.Есть ли более изящные методы?

[illuzor]

Можно конечно это делать один раз при создании экземляра A.Но как-то оно кажется кривым т.к. табличка в будущем может понадобится другим классам.

Как-то нелогично звучит. Если при первом использовании переменные инициализируются, то больше их инициализировать не нужно и любые экземпляры смогут их использовать.

Можно, например, инициализировать переменные через паблик статик метод при запуске приложения.
Или вообще захардкодить значения, чтобы не пришлось ничего вычислять.

[undefined]

Значения могут потребоваться еще ДО создания первого экземпляра А.Не хотелось бы что бы совершенно несвязанные классы зависили от создания чужих экземпляров.

Добавлено через 39 минут
нужно нечто типа блока static {...} в жаве

[Bletraut]

Сообщение от illuzor

...Можно, например, инициализировать переменные через паблик статик метод при запуске приложения.

Поддерживаю, других наиболее уместных решений не вижу.

[wvxvw]

Не знаю как сейчас, несколько лет назад можно было писать код статической инициализации после объявления package. Т.е. например так:

package foo {
    public class Foo {
        public static var foo:Foo;
    }
}
import foo;
Foo.foo = new Foo();

[undefined]

wvxvw,прокатило как раз то, что надо.Благодарю

[caseyryan]

Есть еще вариант сделать обычный класс синглтон. И через него дергать все методы

[faraday]

почему не кешировать значения по мере необходимости?

private static var sins:Object={};
public static var sin(val:Number){
 return sins[val]||(sins[val]=Math.sin(val))
}

[undefined]

тоже вариант.Только нужен контроль за размерами таблички

[Nooob]

Аналог блока static в джаве это вызов static функции в месте определения static полей

package
{
	public class F
	{
		public static const a:Vector.<int> = new Vector.<int>();
		private static function b():void
		{
			for(var i:int = 0; i < 10; ++i)
			{
				a.push(i);
			}
		}
		b();
	}
}

Есть еще такие варианты:

package
{
	public class F
	{		
		public static const c:Vector.<int> = function():Vector.<int>
		{
			var v:Vector.<int> = new Vector.<int>();
			for(var i:int = 0; i < 10; ++i)
			{
				v.push(i);
			}
			return v;
		}();
	}
}

package
{
	public class F
	{
		public static const d:Vector.<int> = new Vector.<int>();
		d.push(0);
		d.push(1);
		d.push(2);
		d.push(3);
		d.push(4);
		d.push(5);
	}
}

Вызываться будет по разному, во FlexSDK при первом обращении к классу, в AirSDK после запуска