Как программно остановить работу скрипта снегопада при нажатии на кнопку?

[Vladislav1983]

Здравствуйте! Делаю открытку со снегопадом. Скрипт снегопада нашел в интернете. Снегопад запускается в середине открытки. На открытке в конце ролика есть кнопка "Повторить просмотр", при нажатии на которую происходит возврат к первому кадр и все начинается снова, но снегопад все равно продолжается. А нужно, чтобы он также останавливался и начался в середине открытки.

Скрипт при нажатии на кнопку "Повторить просмотр":

button_1.addEventListener(MouseEvent.CLICK, fl_ClickToGoToAndPlayFromFrame);
 
function fl_ClickToGoToAndPlayFromFrame(event:MouseEvent):void
{
	gotoAndPlay(1);
}
 
button_1.addEventListener(MouseEvent.CLICK, fl_ClickToStopAllSounds);
 
function fl_ClickToStopAllSounds(event:MouseEvent):void
{
	SoundMixer.stopAll();
}

Скрипт снегопада:

var snowflakes:Array = new Array();
var snowflakeProps:Dictionary= new Dictionary(true);
var max_snowsize:Number = 0.04;
// Количество снежинок
var snowflakesCnt:Number = 40;
var oheight:Number;
var owidth:Number;
init();
function init():void {
 
        // Задаем ширину и высоту области, где будет идти снег, она будет равна размерам нашей флэшки
	owidth = 549;
	oheight = 547;
 
	for (var i:int=0; i<snowflakesCnt; i++) {
 
		var t:MovieClip = new SnowFlake();//
		t.name = "snowflake"+i;
 
		t.alpha = .2+Math.random()*.9;
		t.x = -(owidth/2)+Math.random()*(1.5*owidth);
		t.y = -(oheight/2)+Math.random()*(1.5*oheight);
		t.scaleX = t.scaleY=.5+Math.random()*(max_snowsize*5);
		var o:Object = new Object();
		//Скорость и горизонтальное перемещение снежинок
		o.k = 1+Math.random()*4;
		o.wind = -1.5+Math.random()*(1.2*2);
 
		snowflakeProps[t] = o;
 
		addChild(t);
		snowflakes.push(t);
	}
	addEventListener(Event.ENTER_FRAME, snowFlakeMover);
}
function shakeUp():void{
	for (var i:int=0; i<snowflakes.length; i++) {
		var t:MovieClip = snowflakes[i] as MovieClip;
		t.x = -(owidth/2)+Math.random()*(1.5*owidth);
		t.y = -(oheight/2)+Math.random()*(1.5*oheight);
	}
}
function snowFlakeMover(evt:Event):void {
	var dO:MovieClip;
	var o :Object;
	if(visible && parent.visible){
	for (var i:int = 0; i < snowflakes.length; i++) {
		dO = snowflakes[i] as MovieClip;
		o = snowflakeProps[dO];
		dO.y += o.k;
		dO.x += o.wind;
		if (dO.y>oheight+10) {
 
			dO.y = -20;
 
		}
		if (dO.x>owidth+20) {
 
			dO.x = -(owidth/2)+Math.random()*(1.5*owidth);
			dO.y = -20;
 
		} else if (dO.x<-20) {
 
			dO.x= -(owidth/2)+Math.random()*(1.5*owidth);
			dO.y = -20;
		}
 
	}
	}
}

[Bletraut]

в кнопку добавить

removeEventListener(Event.ENTER_FRAME, snowFlakeMover);
 
	for (var i:int=0; i<snowflakes.length; i++) {
		var t:MovieClip = snowflakes[i] as MovieClip;
                t.parent.removeChild(t);
	}

[Godwarlock]

А лучше так

for each (var t:MovieClip in snowflakes) {
                t.parent.removeChild(t);
	}