Рекурсивный поиск элемента вглубь контейнера

[Serg65535]

Вечер добрый, господа.

Я получаю от дизайнера уже готовый символ в виде swc-библиотеки, внутри которого где-то есть интересующий меня элемент. Глубина его вложения заранее не известна.

Вопрос: вы не встречали готового решения (оптимального по скорости) поиска чайлда по имени внутри контейнера на неизвестной заранее глубине? Или надо самому писать рекурсивный обход (мне не трудно, просто не хочу изобретать велосипед).

Спасибо.

Собственно, там возможны вариации с преобразованием типов (DisplayObject <-> DisplayObjectContainer) и с тем, делать ли это в виде функции, или встраивать в прототип. Вдруг кто-то уже видел хорошее решение?

[udaaff]

Хорошим решением было бы договориться с дизайнером, чтобы он адекватные swc вам присылал.

[Serg65535]

Это да, но в ряде случаев символ требуется упаковать ещё в один символ, дабы сделать глобальный эффект какой-нибудь. Да и библиотека большая. Мне не трудно влезть в исходники и поглядеть точное расположение нужного объекта, но 1) я не хочу жёстко вбивать в код привязку к конкретной реализации графики, и 2) на стадии прототипирования игры это лишняя трата сил и времени, учитывая, что графика очень часто обновляется.

И в любом случае - это не решение вопроса, а его избегание.
Согласитесь, это отличная специфика русских форумов получать на вопросы ответы в духе "а нафига вам?" и "лучше поставь [название продукта]".

[mayakwd]

 
public static function findChild(parentObject : DisplayObjectContainer, childName : String) : DisplayObject {
			var i : int = parentObject.numChildren;
			while (i--) {
				var child : DisplayObject = parentObject.getChildAt(i);
				if (child.name == childName)
  					return child; 
				if (child is DisplayObjectContainer) {
					child = findChild(child as DisplayObjectContainer, childName);
					if (child)
  						return child;
				}
			}
			return null;
		}

[etc]

mayakwd, я бы всё же использовал бы ещё и родной getChildByName в самом начале. Нет смысла гонять цикл, если в контейнере уже есть ребенок с нужным именем.

[mayakwd]

а да, не учел, спасибо за дополнение.

[Serg65535]

mayakwd! Спасибо огромное!

Я примерно в ту же сторону думал (только через for()) но у меня были очень большие сомнения по поводу корректности подстановки типов DisplayObjectContainer вместо DisplayObject и наоборот, да и честно говоря я думал - может существует более универсальное решение, чем тупо рекурсия. Опыта программирования на AS пока не так много Мигрирую с шарпа активно

Ещё раз большое спасибо всем!

Добавлено через 4 часа 26 минут
Финальный вариант функции:

public function findChild(parentObject: DisplayObjectContainer, childName: String): DisplayObject {
	var child: DisplayObject = parentObject.getChildByName(childName);
	if (child) return child;			
	var i: int = parentObject.numChildren;
	while (i--) {
		child = parentObject.getChildAt(i);
		if (child.name == childName) return child;
		if (child is DisplayObjectContainer) {
			child = findChild(child as DisplayObjectContainer, childName);
			if (child) return child;
		}
	}
	return null;
}