Карта... слой под слоем... - Страница 7

Хемуль · 11.10.2006, 19:15

2 Makak:
Если в центре флешки, ровнять нужно относительно сцены (Stage).
Только это уже не мувиклип.

Makak · 11.10.2006, 21:07

эээ ... ууу ... непонял

Хемуль · 11.10.2006, 23:43

2 Makak:
Важно понимать разницу между _root'ом и сценой. _root - это главный мувиклип. Именно мувиклип, а не что-то невообразимо великое. Пока вы не добавите в _root чего-нибудь, он будет пустым и, как любой пустой мувиклип, будет иметь размеры 0х0. Сцена же - это и есть тот прямоугольничек, размеры которого вы задаёте в редакторе. Поэтому я и написал выше, что при необходимости отцентрировать мувиклип относительно центра всей флешки, правильно будет центрировать его относительно сцены, работая при этом с обьектом Stage.
Следующий пример демонстрирует то, как происходит добавление мувиклипов в _root и как это отражается на его размерах. Если раберётесь в коде и увидите, что выводит trace, поймёте. У нас тут просто происходит добавление в _root прямоугольного мувиклипа. До и после добавления размеры _root'а трейсятся.

Код:

trace("## BEFORE MC ADDING ##");
traceMovieClipDimensions(_root);
var clip1:MovieClip = createRectangleMovieClip("clip1", _root, _root.getNextHighestDepth(), 70, 10, 120, 100, 0xff0000, 100);
trace("## AFTER MC ADDING ##");
traceMovieClipDimensions(clip1);
traceMovieClipDimensions(_root);

function traceMovieClipDimensions(mc:MovieClip)
{
	trace(mc + " dimensions: " + mc._width + "x" + mc._height);
}

function createRectangleMovieClip(newName:String, parentClip:MovieClip, parentClipDepth:Number, newX:Number, newY:Number, newWidth:Number, newHeight:Number, newColor:Number, newAlpha:Number):MovieClip
{
	var newClip:MovieClip = parentClip.createEmptyMovieClip(newName, parentClipDepth);
	newClip.beginFill(newColor);
	newClip.moveTo(0, 0);
	newClip.lineTo(newWidth, 0);
	newClip.lineTo(newWidth, newHeight);
	newClip.lineTo(0, newHeight);
	newClip.lineTo(0, 0);
	newClip.endFill();
	newClip._x = newX;
	newClip._y = newY;
	newClip._alpha = newAlpha;
	return newClip;
}

Makak · 13.10.2006, 01:13

поначалу был в шоке

... но потом разобрался ...

Спасибо за пример ))))