как объеденить 2 класса в один

[r_r_f_r]

:void

означает что функция ничего не возвращает, если же вообще ничего не писать

просто нужно было убрать :void

то это не позволяет компилятору типизировать код на этапе компиляции, и типизация будет происходить на этапе выполнения кода, что потребует дополнительных затрат процессорного времени, т.е. это далеко не самый хороший выход.

[droch_fhoula]

ну а что же тогда выход?
по другому у меня не получается.

[r_r_f_r]

А в чём состоит решаемая задача? В создании прелоадера и отключения контекстного меню?

[droch_fhoula]

да именно так
а то у меня получается либо одно либо другое

[RandomUser]

А я вообще никогда не использую void в конструкторах...

[r_r_f_r]

Index.as - выполняет роль лоадера и собсна скрывает меню.

package {
	import flash.display.Graphics;
	import flash.display.Loader;
	import flash.display.LoaderInfo;
	import flash.display.Sprite;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.events.Event;
	import flash.events.IOErrorEvent;
	import flash.events.ProgressEvent;
	import flash.net.URLRequest;
	import flash.text.TextField;
	import flash.text.TextFieldAutoSize;
	import flash.text.TextFormat;
 
	public class Index extends Sprite
	{
		private var _loader:Loader;
		private var _tf:TextField;
 
		public function Index()
		{
			super();
			setStage();
 
			_loader = new Loader();
			_loader.load(new URLRequest('MainMovie.swf'));
			_loader.contentLoaderInfo.addEventListener(Event.COMPLETE,onComplete);
			_loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR,onIOError);
			_loader.contentLoaderInfo.addEventListener(ProgressEvent.PROGRESS,onProgress);
 
			gr = graphics;
 
			_tf = new TextField();
			addChild(_tf);
			_tf.selectable = false;
			_tf.defaultTextFormat = new TextFormat('Tahoma', 12);
			_tf.autoSize = TextFieldAutoSize.LEFT;
		}
 
		private static var gr:Graphics;
		private function onProgress(e:ProgressEvent):void
		{
			gr.clear();
			gr.beginFill(0,1);
			gr.drawRect(0,0,stage.stageWidth/e.bytesTotal*e.bytesLoaded,stage.stageHeight);
 
			_tf.text = String(e.bytesLoaded/e.bytesTotal*100);
			_tf.x = (stage.stageWidth-_tf.width)/e.bytesTotal*e.bytesLoaded;
		}
 
		private function onIOError(e:Event):void
		{
			trace (e);
		}
 
		private function onComplete(e:Event):void
		{
			gr.clear();
			removeChild(_tf);
			_tf = null;
 
			addChild((e.target as LoaderInfo).content);
		}
 
		private function setStage():void
		{
			stage.align = StageAlign.TOP_LEFT;
			stage.scaleMode = StageScaleMode.NO_SCALE;
			stage.showDefaultContextMenu = false;
		}
	}
}

MainMovie.as - загружаемый мувик.

package
{
	import flash.display.Graphics;
	import flash.display.Sprite;
	import flash.events.Event;
 
	public class MainMovie extends Sprite
	{
		public function MainMovie()
		{
			super();
			addEventListener(Event.ADDED_TO_STAGE,onAddedToStage);
		}
 
		private function onAddedToStage(e:Event):void
		{
			var gr:Graphics = graphics;
 
			gr.beginFill(0x444444,1);
			gr.drawRect(0,0,stage.stageWidth,stage.stageHeight);
		}
	}
}