Градиентная заливка BitmapData

[nbno]

Здравствуйте.

Задача: Создать диагональную штриховку, на которую бы накладывался градиент. Программно.
Как я это пытаюсь сделать:

Создаю градиент (400x400):

var gradient:Shape = new Shape();
var matrix:Matrix = new Matrix();
matrix.createGradientBox(400, 400, Math.PI/2, 0, 0);
gradient.graphics.beginGradientFill(GradientType.LINEAR, [0x00FF00, 0x0000FF], [1, 1], [0, 255], matrix);
gradient.graphics.drawRect(0, 0, 400, 400);
addChild(gradient);

Создаю штриховку:

//заполняем BitmapData
var bitmapdata:BitmapData = new BitmapData(3, 3, true, 0x000000);
bitmapdata.setPixel32(0, 1, 0xffffffff);
bitmapdata.setPixel32(1, 0, 0xffffffff);
bitmapdata.setPixel32(2, 2, 0xffffffff);
 
//заливаем им Shape, который потом будет маской
var mask:Shape = new Shape();
mask.graphics.beginBitmapFill(bitmapdata);
mask.graphics.drawRect(0, 0, 400, 400);
addChild(mask);

Пытаюсь сделать mask маской gradient:

gradient.mask = mask

Результат: маска не применяется (mask исчезает, gradient остается полностью видимым). Есть ли более правильные/корректные или альтернативные варианты сделать тоже самое?

[saikspaik]

Я попробовал код, у меня он заработал, нужно было только переменную mask переименовать (иначе конфликт происходит).
Правда про штриховку не совсем понял, иллюстрация желаемого результата только ускорит решение проблемы.

[nbno]

С переименованием или без у меня результат один и тот же.
Иллюстрации, учитывая, что фон черный:

Создаю градиент:

gradient:Shape

Создаю штриховку (белого цвета):

mask:Shape

Пытаюсь сделать mask маской gradient:

Результат: маска не применяется (mask исчезает, gradient остается полностью видимым)

[Wolsh]

чтобы учитывалась прозрачность, надо кешировать в битмап (.casheAsBitmap = true)

var gradient:Shape = new Shape();
var matrix:Matrix = new Matrix();
matrix.createGradientBox(400, 400, Math.PI/2, 0, 0);
gradient.graphics.beginGradientFill(GradientType.LINEAR, [0x00FF00, 0x0000FF], [1, 1], [0, 255], matrix);
gradient.graphics.drawRect(0, 0, 400, 400);
gradient.cacheAsBitmap = true;
addChild(gradient);
//заполняем BitmapData
var bitmapdata:BitmapData = new BitmapData(3, 3, true, 0x000000);
bitmapdata.setPixel32(0, 1, 0xffffffff);
bitmapdata.setPixel32(1, 0, 0xffffffff);
bitmapdata.setPixel32(2, 2, 0xffffffff);
 
//заливаем им Shape, который потом будет маской
var strokeMask:Shape = new Shape();
strokeMask.graphics.beginBitmapFill(bitmapdata);
strokeMask.graphics.drawRect(0, 0, 400, 400);
strokeMask.cacheAsBitmap = true;
addChild(strokeMask);
gradient.mask = strokeMask;

[nbno]

Первоначальные варианты реализации включали casheAsBitmap, но видимо в другой интерпретации:)
Большое спасибо, все работает замечательно.