Прозрачный курсор

[Wolsh]

Возможно, курсор так реализован, что из предоставленных битмап берется битмапдата, а на нее то альфа конечно не влияет) Тогда либо перерисовывать сами картинки в редакторе, либо обрабатывать битмапдату, уменьшая непрозрачность пикселов.

Добавлено через 4 минуты
Но вообще, если метод HardCodera не сработал, то действительно странно.

[HardCoder]

alex001, да, а почему нельзя создать картинки изначально полупрозрачными?

[alex001]

дело в том что alpha зависит от растояния курсора от одого объекта, и наверное легче все-таки сделать программно, чем делать 101 изображение (включая полную прозрачность), хотя если другого не придумаь, придется так. не знаете с помощью какой программы можно сделать это? вручную с фотошопом долговато получится.

[Zebestov]

Подготовить серию BitmapData с разной прозрачностью можно и непосредственно в коде.
А что до фотошопа, то вроде бы Action и Batch на месте.

[Wolsh]

var bitmapDatas:Vector.<BitmapData>  = new Vector.<BitmapData> (1,true);
var bitmap:Bitmap = new NewCursor();
var bmd:BitmapData = bitmap.bitmapData;
var bmd2:BitmapData = new BitmapData(bmd.width, bmd.height, true, 0x00000000);
var alphaBMD:BitmapData = new BitmapData(bmd.width, bmd.height, true, 0x88000000);
bmd2.copyPixels(bmd, bmd.rect, new Point(), alphaBMD, new Point(), true);
bitmapDatas[0] = bmd2;
 
var cursorData:MouseCursorData = new MouseCursorData();
cursorData.hotSpot = new Point(3,3);
cursorData.data = bitmapDatas;
Mouse.registerCursor("New", cursorData);
Mouse.cursor = "New";

[Zebestov]

Так речь о статичном курсоре вообще? Тогда, конечно же, "на лету"!

[alex001]

да, речь о статичном. код Wolsh работает прекрасно, за что огромное спасибо. количество первых двух нулей после x это значение альфы, FF - 100%. теперь, наверное, последний вопрос. альфа должна быть равна переменной, но как это перевести в 0x**000000? попробовал через

var alphaStr:String = "0x" + varX + "000000";

а потом перевести из string в нужный формат, но какой? как-то примитивно, но единственное что пришло в голову.

[Zebestov]

varX <<= 24

При условии, что varX целое и 0 <= varX <= 255.

[Wolsh]

другой вариант – через контейнер.

var bitmapDatas:Vector.<BitmapData>  = new Vector.<BitmapData> (1,true);
var bitmap:Bitmap = new NewCursor();
var s:Sprite = new Sprite();
s.addChild(bitmap);
 
var bmd:BitmapData = new BitmapData(s.width, s.height, true, 0x00000000);
bitmap.alpha = 0.5;
bmd.draw(s);
bitmapDatas[0] = bmd;

[alex001]

Wolsh, огромное спасибо, теперь все работает! Zebestov, HardCoder, тоже благодарю!