Предок не приводится к наследнику. Почему?

[zhoran]

Хочу расширить Array. Почитал Мука, посмотрел хелп. Сделал так:

public dynamic class MyArray extends Array
{
 
  public function MyArray(... args)
  {
 
  }
 
  public function compact():Array {
    var arr:Array = this.filter(
      function (element:*, index:int, arr:Array):Boolean {
        return (element != null);
      })
    return arr;
  }
 
}

А это не работает:

var my_arr:MyArray = [null, null, 2, 3];
//Пишет: Implicit coercion of a value with static type Array to a possibly 
//unrelated type utils:MyArray.
 
var my_arr:MyArray = MyArray ([null, null, 2, 3]); 
//Пишет rte: [Fault] exception, information=TypeError: Error #1034: 
//Ошибка типа Coercion: невозможно преобразовать []@156d291 в utils.MyArray
 
var my_arr:MyArray = [null, null, 2, 3] as MyArray;
// Не ругается, но my_arr равен null

как можно создать объект MyArray из объекта Array ?
и в чем разница ... as MyArray и MyArray (...) ?

[Dukobpa3]

public dynamic class MyArray extends Array 
{	
	public function MyArray(... args) 
	{
		super();
		for (var i:int = 0 ; i < args.length ; i ++ ) {
			this.push(args[i]);
		}		
	}	
}

var arr:MyArray = new MyArray(1, 2, 3, 4);
trace(arr);
//1,2,3,4
 
arr.push(5);
trace(arr);
//1,2,3,4,5
 
arr[5] = 6;
trace(arr);
//1,2,3,4,5,6

А как заставить чтоб работало:

var arr:MyArray = [1, 2, 3, 4]

Я не знаю

Добавлено через 5 минут

делай

Код AS3:

public function MyArray(... args)
{
super(args);
}

Нет. не делай Этот код всунет тебе в первый элемент массива, тот массив который ты ему вручил в конструкторе.

например если сделаешь вот так:

var my_arr:MyArray = MyArray ([null, null, 2, 3]);

то получишь такую конструкцию:

1. [null, null, 2, 3]

а потом если сделаешь к примеру:

my_arr.push(22);
my_arr.push(33);
my_arr.push(44);

то получится примерно следующее:

1. [null, null, 2, 3]
2. 22
3. 33
4. 44

[zhoran]

Спасибо за помощь!
Немного переделал, теперь у меня так:

public dynamic class MyArray extends Array
{
 
  public function MyArray(arr:Array)
  {
    arr.forEach(this.push_element);
  }
 
  private function push_element(element:*, index:int, arr:Array):void {
    this.push(element);
  };
}
 
var my_arr:MyArray = new MyArray([null, null, 2, 3]);

[Obi]

Простите, а с чего массив должен реализовывать методы, объявленные в его наследнике? Вы пишете var arr:MyArray = new Array(). Array не наследует поведение MyArray, в то время как MyArray поведение Array — наследует. Следовательно, вот так будет работать: var arr:Array = new MyArray(); а так: var arr:MyArray = new Array() — нет.

[zhoran]

Простите, а с чего массив должен реализовывать методы, объявленные в его наследнике?

Ну, я подумал, а почему бы за кулисами при приведении массива к моему массиву автоматом не прикручивались бы дополнительные методы. Ведь переменных экземпляра я не объявлял.

[BlooDHounD]

public dynamic class MyArray extends Array {
	public function MyArray(...args) {
		super();
		super.push.apply( null, args );
	}
}

[semenyakinVS]

Потому, что это противоречит концепции ООП. Предок в принципе не может приводиться к наследнику. А сделать так, как вы желаете нельзя.

var testMyArr:MyArr = [1, 2, 3];   <=>   var testMyArr:MyArr = new Array(1, 2, 3);

Вот если бы в AS3 можно было перегружать операторы, или были бы макросы - пожалуйста... Хотя, и тогда не совсем.

[Dukobpa3]

  public function MyArray(arr:Array)
  {
    arr.forEach(this.push_element);
  }

Вот этого делать необязательно. "args" - уже и так сам по себе массив. можно писать вот так:

  public function MyArray(... args)
  {
    args.forEach(this.push_element);
  }

ну и BlooDHounD поизящнее метод предложил, вне конкуренции

[zhoran]

Сообщение от BlooDHounD

super.push.apply( null, args );

Это круто! И при этом инициализация делается вот так:

var my_arr:MyArray = new MyArray(null,null,2,3);

Добавлено через 3 минуты

Сообщение от Dukobpa3

Вот этого делать необязательно. "args" - уже и так сам по себе массив.

точно

Добавлено через 10 минут

Сообщение от semenyakinVS

Потому, что это противоречит концепции ООП. Предок в принципе не может приводиться к наследнику.

Это понятно, но согласитесь, в простом случае, когда конструктор явно не объявлен в наследнике (компилятору известно, что новых переменных экземпляра нет), казалось бы чисто технически ничто не мешает реализовать в компиляторе такое приведение предка к потомку. Просто прикрутить к даным экземпляра расширенную потомком таблицу методов. ?

[semenyakinVS]

Сообщение от Dukobpa3

var arr:MyArray = new MyArray(1, 2, 3, 4);
 
arr[5] = 6;
trace(arr);
//1,2,3,4,5,6

Оператор [] будет работать в таком случаи? Это хорошо...