класс SWFAddressEvent и ошибка 5007

[Di_al]

Возникла такая проблема:
есть SWFAddressEvent.as,SWFAddress.as и main.fla файлом. При компиляции флеш выдает ошибку 5007:An ActionScript file must have at least one externally visible definition. И при этом указывает на класс SWFAddressEvent, который в наглую скачан с безграничных просторов интернета. Код класса выглядит следующим образом:

import SWFAddress;
 
class SWFAddressEvent {
 
    public static var INIT:String = 'init';
    public static var CHANGE:String = 'change';
 
    private var _type:String;
    private var _value:String;
    private var _path:String;
    private var _pathNames:Array;
    private var _parameters:Object;
    private var _parametersNames:Array;
 
    public function SWFAddressEvent(type:String) {
        _type = type;
        _value = SWFAddress.getValue();
        _path = SWFAddress.getPath();
        _pathNames = SWFAddress.getPathNames();
        _parameters = new Array();
        _parametersNames = SWFAddress.getParameterNames();
        for (var i:Number = 0; i < _parametersNames.length; i++) {
            _parameters[_parametersNames[i]] = SWFAddress.getParameter(_parametersNames[i]);
        }        
    }
 
    public function get type():String {
        return _type;
    }
 
    public function get target():Object {
        return SWFAddress;
    }
 
    public function get value():String {
        return _value;
    }
 
    public function get path():String {
        return _path;
    }
 
    public function get pathNames():Array {
        return _pathNames;
    }
 
    public function get parameters():Object {
        return _parameters;
    }
 
    public function get parametersNames():Array {
        return _parametersNames;
    }    
}

Так как я только с недавних пор пытаюсь пересесть с Action Script2.0 на 3.0, то даже не особо могу определить в чем кроется ошибка: то ли в расположении файлов, то ли чего то не хватает в самом коде?

[tsarapkabel]

class SWFAddressEvent {

Заменить на

public class SWFAddressEvent {

[Di_al]

Сообщение от tsarapkabel

Заменить на

public class SWFAddressEvent {

Хмммм..... а теперь он выдал новую ошибку, что атрибуты класса могут использоваться только внутри %(
Звучит вот так:

C:\Users\Xmel\Desktop\Anls\5\SWFAddressEvent.as, Line 11	1114: The public attribute can only be used inside a package.

[tsarapkabel]

В самом начале добавить

package {

и закрыть в конце.

[Di_al]

Пробовала. Увы ошибка 5007 сохраняется

[tsarapkabel]

Вот так всё работает, при условии, что класс SWFAddress импортируется.

package {
 
	import SWFAddress;
 
	public class SWFAddressEvent {
 
		public static var INIT:String = 'init';
		public static var CHANGE:String = 'change';
 
		private var _type:String;
		private var _value:String;
		private var _path:String;
		private var _pathNames:Array;
		private var _parameters:Object;
		private var _parametersNames:Array;
 
		public function SWFAddressEvent(type:String) {
			_type = type;
			_value = SWFAddress.getValue();
			_path = SWFAddress.getPath();
			_pathNames = SWFAddress.getPathNames();
			_parameters = new Array();
			_parametersNames = SWFAddress.getParameterNames();
			for (var i:Number = 0; i < _parametersNames.length; i++) {
				_parameters[_parametersNames[i]] = SWFAddress.getParameter(_parametersNames[i]);
			}        
		}
 
		public function get type():String {
			return _type;
		}
 
		public function get target():Object {
			return SWFAddress;
		}
 
		public function get value():String {
			return _value;
		}
 
		public function get path():String {
			return _path;
		}
 
		public function get pathNames():Array {
			return _pathNames;
		}
 
		public function get parameters():Object {
			return _parameters;
		}
 
		public function get parametersNames():Array {
			return _parametersNames;
		}
	}
}

[Di_al]

Кхм.... И как же тогда вывернуться из сложившейся ситуации??? Попробовала поперемещать класс он либо говорит, что класс не в той папке, либо, если удалить, что класс не найден. Когда класс с ним рядом, ошибок импортирования нет. А 5007 все равно осталась

[tsarapkabel]

Выложи SWFAddress.as (можно только код) и main.fla.

[Di_al]

боюсь, что этим обойтись не выйдет-проект довольно масштабный. Выложила его вот сюда
сюда

[tsarapkabel]

Всё работает. Ещё раз по порядку: 1) package 2) две фигурные скобки 3) public 4) сохраняемся 5) profit

Далее он выдаёт кучу ошибок "1046", однако если применить Автоформат (наверху 4-я иконка слева в редакторе кода Flash IDE), останутся только косяки с

ExternalInterface.addCallback('getSWFAddressValue', SWFAddress, ;
				function():String {return this._value});

Полагаю, что уход от анонимных функций решит эту проблему.