Ошибка с onRelease на загружаемом мувике

[_rev]

Есть вот такой код:

var n:Number = 1;
var current_x:Number = 0;
var current_y:Number = 0;
for (var i:Number = 1; i < 150; i++) {
	n = randRange(1, 12);
	this.createEmptyMovieClip("mcImage"+i, this.getNextHighestDepth());
	var my_Loader:MovieClipLoader = new MovieClipLoader()
	my_Loader.loadClip("sq_swf/"+n+".swf", "mcImage"+i);
	_root["mcImage"+i]._x=current_x;
	_root["mcImage"+i]._y=current_y;
	_root["mcImage"+i].onRelease = function() {
  		trace("YEAH!");
	};

Мувики загружаются случайно, при этом на каждого должно вешатся событие, но почему-то не работает. WHY?

[Zik.]

Потому что вы вышаете онРелиз не дождавшись, когда клип загружится

[mooncar]

1. В цикле оставьте только создание пустого мувика и loadClip
2. Используйте один экземпляр MCL. У вас их 150 штук - безумие.
3. Для решения вашей проблемы используйте один общий метод onLoadInit.
Внутри этого метода и координаты меняйте и обработчики назначайте.

Добавлено через 14 минут

var n:Number = 1;
var current_x:Number = 0;
var current_y:Number = 0;
 
this.onLoadInit = function  (target_mc:MovieClip) {
	target_mc._x = current_x;
	target_mc._y = current_y;
	target_mc.onRelease = mcOnRelease;	
};
 
function mcOnRelease () {
	  trace('Я  - контейнер с загруженным мувиком, я зовусь ' + this);
}
 
var my_Loader:MovieClipLoader = new MovieClipLoader();
my_Loader.addListener(this);
 
for (var i:Number = 1; i < 150; i++) {
	n = randRange(1, 12);
	this.createEmptyMovieClip('mcImage' + i, this.getNextHighestDepth());
	my_Loader.loadClip('sq_swf/' + n + '.swf', 'mcImage' + i);
}

В данном случае в роли слушателя выступает объект с текущим таймлайном, например, _root).
Только поскольку координаты контейнерам у вас присваиваются одинаковые, они у вас лепиться один на другой будут.