Удвоенные энтеры (переносы строк) при загрузке обычного многострочно текстового файла

[stringer2008]

Откуда берутся удвоенные переносы строк при загрузке обычного многострочного текстового файла?
Код приведен ниже, а файл можно сделать любой с именем 'Kyiv.txt' и кодировкой UTF-8 с несколькими строками текста.

import flash.display.Sprite;
import flash.events.Event;
import flash.net.URLLoader;
import flash.net.URLRequest;
import flash.text.TextField;
import flash.text.TextFieldAutoSize;
import flash.events.IOErrorEvent;

var loader:URLLoader;

function URLLoader_loadExample() {
	var request:URLRequest = new URLRequest("Kyiv.txt");

	loader = new URLLoader();
	loader.dataFormat = URLLoaderDataFormat.TEXT;
	
	try {
		loader.load(request);
	}
	catch (error:SecurityError)
	{
		trace("A SecurityError has occurred.");
	}

	loader.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);
	loader.addEventListener(Event.COMPLETE, loaderCompleteHandler);
}

function loaderCompleteHandler(event:Event):void {

		try {
			txt.text = loader.data;  // txt - текстовое поле
			trace(loader.data);
		} catch (e:TypeError) {
			trace("Could not parse the file.");
		}
}

function errorHandler(e:IOErrorEvent):void {
	txt.text = "Had problem loading the file.";
}
URLLoader_loadExample();

[WindWalker]

Он и символ с кодом 0D и символ с кодом 0A считает переносом.
Вот пример:

txt1.text = "Hello\nworld";
txt2.text = "Hello\r\nworld";

В первом случае нет пустой строки между словами (только \n).
Во втором случае есть (и \r и \n воспринимаются как переход на новую строку).

Таким образом, нужно провести дополнительную обрпботку - заменить все \r\n на \n.

[stringer2008]

Попробовал вот так, и ничего не помогло:

function loaderCompleteHandler(event:Event):void {

	try {
		var str:String = loader.data;
		str = str.replace("\r\n","");
		txt.text = str;
		trace(str);
	} catch (e:TypeError) {
		trace("Could not parse the file.");
	}
}

[udaaff]

str.replace(/[\n\r]/g, ""); // удалит все символы \n и \r

Можете еще про TextField.condenseWhite почитать, если совсем переносы не нужны.

[etc]

Так вы удалить хотите все переносы или все-таки двойные? Вы внимательно прочитали второй пост?

[stringer2008]

Получилось!!!

function loaderCompleteHandler(event:Event):void {

	try {
		var str:String = loader.data;
		str = str.replace(/(\n\r|\n|\r)+/g,"\n");
		txt.text = str;
		trace(str);
	} catch (e:TypeError) {
		trace("Could not parse the file.");
	}
}

[stringer2008]

Хорошо, что я знаю регулярные выражения, я то долго мучался бы.
Точнее будет:

str = str.replace(/(\n\r|\n|\r){2}/g,"\n");

Adobe могли бы сделать что-то на этот случай, а то гониво получается. Кстати, за решение этой проблемы мне заплатит одна дизайн-студия $50.
Так что я рад Всем спасибо за внимание!

[BlooDHounD]

str = str.replace(/\n\r?/g,"\n");

[WindWalker]

Кстати, очень долго колебался, как же всё-таки правильно: "\n\r" или "\r\n". Никак не мог вспомнить.
Интуиция подсказывала, что всё-таки "\n\r".
Здравый смысл ей вторил: сперва новая строка, а затем уже возврат каретки.

Однакось:

var s:String = "\n\r";
trace (s.charCodeAt(0));
trace (s.charCodeAt(1));

Выдаёт: 10 13
А в файлах (по крайней в винде), всегда идёт 13 10.
Так что "\r\n" - более правильно, хоть и почему-то режет глаз.

[etc]

А если вспомнить обычную печатную машинку, то сначала делался возврат каретки (\r), потом перевод на новую строку (\n).