Движение клипа при клике

[Волгоградец]

Привет. Помогите пожалуйста разобраться с такой проблемой: клип при щелчке мыши движется в то самое место, где произошел клик. Все работает почти хорошо - беда только в том, что если клик произошел прямо над или под клипом (угол равен 90), тогда скорость по y становится чудовищно огромной... Ошибка где-то здесь, но мой мозг не может справиться:

function angle (){
	true_lenx = a - cir._x;//расстояние от места клика до клипа по х
	true_leny = b - cir._y;//расстояние от места клика до клипа по у
	len_x = Math.abs(true_lenx);
	len_y = Math.abs(true_leny);
	tan = len_y/len_x;
	ugol = Math.atan(tan)*180/Math.PI;
	speed_y = Math.tan(ugol*Math.PI/180)*speed_x;
}

[Kikasso]

Наверное происходит деление на 0, со всеми вытекающими.
Попробуйте Math.atan2(dx, dy)

[Wolsh]

Непонятно, зачем Вам угол - просто вычисляйте отдельно смещение по х и у

[Kikasso]

Ай точно. Попробуйте вот это вместо вашего кода. Там три настройки, можно поиграться ))

///// настройки  /////////////////////
//коэффициент трения - от 0 до 1
// 1 - нет трения
// 0 - трение бесконечно
cir.R = .85;
//коэффициент "притяжения" мышки
cir.mouseK = .06;
// коэффициент "тупости", от 0 и выше
// при 0 не тупим
cir.filterK = 2;
//////////////////////////////////////

//начальная скорость
cir.vx = 0; cir.vy = 0;

//крестик/////////////////////////
cross = createEmptyMovieClip( 'cross', 1 );
with(cross){
 lineStyle( 1, 0 ); moveTo( -5, -5 ); lineTo( 5, 5 ); moveTo( 5, -5 ); lineTo( -5, 5 );
}
///////////////////////////////

// реакция на клик
onMouseDown = function (){
	cir.newX = cross._x = _xmouse;
	cir.newY = cross._y = _ymouse;
	cir.onEnterFrame = moveMC;
}

// уровнение движения
function moveMC(){
	// расстояние
	var dx:Number = this.newX - this._x;	var dy:Number = this.newY - this._y;
	// ускорение
	var ax:Number = dx*this.mouseK;	var ay:Number = dy*this.mouseK;
	// скорость
	this.vx += ax;	this.vy += ay;
	// трение
	this.vx *= this.R;	this.vy *= this.R;
	// новая позиция
	var currX:Number = this._x + this.vx;	var currY:Number = this._y + this.vy;
	// отфильрованое перемещение
	this._x = filterVal( this._x, currX, this.filterK );	this._y = filterVal( this._y, currY, this.filterK );	
	// остановка
	if(Math.abs(this.vx)< .5 && Math.abs(this.vy)< .5 && Math.abs(dx)< .5 && Math.abs(dy)< .5 ){
	 delete this.onEnterFrame; 
	 this.vx = 0;	 this.vy = 0;	
   this._x = this.newX;	 this._y = this.newY;
	}
}

// фильтрация
function filterVal( oldval:Number, newval:Number, k:Number ):Number{
	if(k <= 0 )return newval;
	return ( (oldval*k + newval)/(k+1) );
}

[Волгоградец]

Но ведь если смещение по х и у будет одинаковое - тогда движение будет не по кратчайшему пути, т.е. не по гипотенузе. А чтобы оно было таким - я использовал зависимость скорости по у от х.

[udaaff]

Имелось в виду, что надо раскладывать вектор скорости на составляющие по x и по y. Смещаться все будет так как надо.

[Волгоградец]

Точно! Вот я тормоз. Совсем математику забыл.)