проиграть несколько flv файлов

[BoBka_altRUist]

в хелпе по 8-му флэшу есть такой пример для воспроизведения flv

var connection_nc:NetConnection = new NetConnection();
connection_nc.connect(null);
var stream_ns:NetStream = new NetStream(connection_nc);
my_video.attachVideo(stream_ns);
stream_ns.play("video2.flv");

скажите а как сделать чтобы при нажатии на одну кнопку воспроизводился один видеофайл, а при нажатии на другую, другой?

пробовал так:

var connection_nc:NetConnection = new NetConnection();
connection_nc.connect(null);
var stream_ns:NetStream = new NetStream(connection_nc);
my_video.attachVideo(stream_ns);

vid_but_1.onPress = function() {
   stream_ns.play("video1.flv");
};

vid_but_2.onPress = function() {
   stream_ns.play("video2.flv");
};

[iNils: Для оформления своего кода, надо использовать теги [code][/code]]

не работает

[Aziz Zaynutdinoff]

var my_video:Video; // my_video is a Video object on the Stage
var my_nc:NetConnection = new NetConnection();
my_nc.connect(null);
var my_ns:NetStream = new NetStream(my_nc);
my_video.attachVideo(my_ns);
var btn1:MovieClip = this.createEmptyMovieClip("btn1", this.getNextHighestDepth());
var btn2:MovieClip = this.createEmptyMovieClip("btn2", this.getNextHighestDepth());
function DrawBox(_mc:MovieClip):Void{
	with(_mc){
		beginFill(0x000000, 100);
		lineTo(50, 0);
		lineTo(50,50);
		lineTo(0, 50);
		lineTo(0 , 0);
		endFill();
	}
}
DrawBox(btn1);
DrawBox(btn2);
btn1._y = 300;
btn2._y = 300;
btn1._x = 100;
btn2._x = 200;
btn1.onRelease = function(){
	my_ns.play("http://www.comedy.su/promo/videos/11.flv");
}
btn2.onRelease = function(){
	my_ns.play("http://www.comedy.su/promo/videos/12.flv");
}

Если не получиться, я тогда наверное обладатель волшебного Флэша!

P.S.>>>
не забудь положить объект Video на сцену!

P.P.S.>>>
А если ты собираешься проигрывать локальные файлы, то зачем такие заморочки? Поставь на сцену FLVPlayback и радуйся прелестям... Копай Help внимательнее... Тот пример, что я дал ничем не отличается от хелпового.