Как иницализировать свойство target или currentTarget у Event?

[il phoenix]

генерю событие в контроле

private function onSelect_Click(e:Event):void 
{
	dispatchEvent(new Event(Event.SELECT));
}

не могу понять как присвоить свойствам target или currentTarget ссылку на текущий контрол, чтобы передать слушателю события, прошу прощения если тема поднималась, но найти не смог

[alatar]

Никак. Они инициализируются автоматически.

[gloomyBrain]

package  {
 
	import flash.events.Event;
 
	/**
	 * 
	 * 
	 * @author gloomyBrain
	 */
	public class MyEvent extends Event {
 
		private var _myTarget:Object = null;
 
		public function MyEvent(type:String, customTarget:Object, bubbles:Boolean = false, cancelable:Boolean = false) {
 
			super(type, bubbles, cancelable);
 
			_myTarget = customTarget;
 
		}
 
		override public function get target():Object {
			return _myTarget;
		}
 
		public override function clone():Event {
			return new MyEvent(type, _myTarget, bubbles, cancelable);
		} 
 
		public override function toString():String {
			return formatToString("MyEvent", "type", "target", "bubbles", "cancelable", "eventPhase"); 
		}
 
	}
 
}

и потом где-то в коде:

super.addEventListener("hello, stage!", onStageGreet);
super.dispatchEvent(new MyEvent("hello, stage!", super.stage));
 
...
 
private function onStageGreet(event:Event):void {
	trace(event.target == super.stage); // true
}

[~~~]

Сообщение от gloomyBrain

Код AS3:
"hello, stage!"

Событие "hello, stage!" - это жёстко, ух

[Psycho Tiger]

gloomyBrain, не всё так круто как кажется на самом деле. Из за того, что EventDispatcher дёргает clone тогда, когда установлен target в твоём примере в хэндлер долетает клон события MyEvent, а не то, что ты создал через new строчкой ниже подписки.

[gloomyBrain]

Несмотря на это, я вроде ответил на вопрос автора.
Никто же не мешает переопределить currentTarget тем же макаром, или даже публичный доступ к нему прикрутить.

ЗЫ
О чем мы говорим? =) все равно проще добавить своих свойств своему событию

[Psycho Tiger]

Несмотря на это, я вроде ответил на вопрос автора.

Ага. Но я считаю нужным давая такой совет дополнить его описанием side-effects.

О чем мы говорим? =) все равно проще добавить своих свойств своему событию

Согласен. Но, вполне возможно, автор пишет свой Composite с bubbling`ом.

[il phoenix]

понял, спасибо