В классе не срабатывает метод клипа

[Волгоградец]

Привет! Друзья, помогите разобраться со следующей проблемой:

import mx.utils.Delegate;

class RoundMenu {
	private var _mc:MovieClip;
	private var clip:MovieClip;
	private var flag:Boolean;

	public function RoundMenu (mc:MovieClip, inst:String) {
		_mc = mc;
		clip = _mc.attachMovie (inst, inst, _mc.getNextHighestDepth ());
		clip.onEnterFrame = Delegate.create (this, menu_move);
	}

	private function menu_move ():Void {
		trace (flag);
		clip.onRollOver = function () {
			flag = true;
		};
		clip.onRollOut = function () {
			flag = false;
		};
	}
}

Это сильно урезаный класс... Вобщем trace выдает undefined, хотя остальные методы клипа работают замечательно, например clip._x, clip._yscale и т.д.

[chingachgoog]

А если вместо clip.onRollOver поставить this.onRollOver?
И еще странно в цикле каждый раз назначать обработчик.

[Волгоградец]

Если использовать this - ругается что нет такого метода.

И еще странно в цикле каждый раз назначать обработчик.

Вот это я ступил - обработчик же вещает событие как только это событие случится... Спасибо.

Подождите... А как мне эти условия в классе задать? Если я в конструкторе напишу, то только один раз срабатают? Через Delegate придется?

[iNils]

import mx.utils.Delegate;

class A {
	private var _mc:MovieClip;
	private var clip:MovieClip;
	private var flag:Boolean;

	public function A(mc:MovieClip, inst:String) {
		_mc = mc;
		clip = _mc.attachMovie (inst, inst, _mc.getNextHighestDepth ());
		clip.onEnterFrame = Delegate.create (this, menu_move);
		clip.onRollOver = Delegate.create (this, onRollOver);
		clip.onRollOut = Delegate.create (this, onRollOut);
	}

	private function menu_move ():Void {
		trace (flag);
	}
	private function onRollOver () {
		flag = true;
	};
	private function onRollOut () {
		flag = false;
	};
}

[Волгоградец]

Как просто. Спасибо.