Баллистическая задача

[iflamberg]

Не знаю, правильно ли я выбрал раздел, сделаю пост сюда.

Классика, из пункта А со скоростью V под углом тета вылетает снаряд.

Для этой задачи можно использовать школьную параметрическую формулу от времени:

Vx = V * cos(teta);
Vy = V * sin(teta);
x(t) = x0 + Vx*t;
y(t) = y0 + Vy*t - g*t*t/2; //g - гравитация

Но, если, мне все равно изобразить на экране летящий снаряд, то логично просто каждый кадр летящего снаряда:

x = x+Vx;
y = y+Vy;
Vy -= g;

Математика пятого класса, как-никак. Да и, собственно Vy = y'(t) = v - gt, т.е. одно и то же.

Проблема в том, что траектории варианта 1 и варианта 2 не совпадают. А так как алгоритмы, типа: "знаем скорость и конечную точку, посчитаем угол"(нужны для расчета выстрела компьютерного оппонента) опираются на t, то снаряд промахивается. Наглядно рисуем траектории:

var x0:Number = 100;
var y0:Number = 200;
var angle:Number = -45;
var gravity:Number = 3;
var t:Number = 100;
var v:Number = 25;
 
var vx0:Number = v*Math.cos(angle * Math.PI/180);
var vy0:Number = v*Math.sin(angle * Math.PI/180);
 
graphics.lineStyle(1,0xff0000);
graphics.moveTo(x0,y0);
for (var i:Number =0; i<t; i++){
	graphics.lineTo(x0+vx0*i,y0+vy0*i + gravity*i*i*0.5);
}
 
graphics.lineStyle(1,0x00ff00);
graphics.moveTo(x0,y0);
var curx:Number = x0, cury:Number = y0, vy:Number = vy0;
for (i = 0; i<t; i++){
	curx+=vx0; 
	cury+=vy;
	vy+=gravity;
	graphics.lineTo(curx,cury);
}

Вот я и думаю, откуда вылазит такая ошибка. Это накопление погрешности, или ошибка в расчетах.

[maxkar]

y = y+Vy;

Вот это вот неправильно. У вас же скорость за "единицу" времени непостоянно. Поэтому при умножении "мгновенной" скорости на промежуток времени получается ошибка.

[iflamberg]

Слушай, а точно. Если уменьшить шаг:

graphics.lineStyle(1,0x00ff00);
graphics.moveTo(x0,y0);
var curx:Number = x0, cury:Number = y0, vy:Number = vy0;
for (i = 0; i<t; i+=0.1){
	curx+=vx0*0.1; 
	cury+=vy*0.1;
	vy+=gravity*0.1;
	graphics.lineTo(curx,cury);
}

То погрешность значительно уменьшается.

[maxkar]

Ну так то, что точность растет, вполне естественно. Вы на самом деле численно интеграл скорости по времени считаете . И при уменьшении интервала (и увеличения их количества) точность возрастает. В пределе как раз и будет точное значение. Это все из определения интеграла следует.

[-De-]

Для данной конкретной формулы можно ошибку при числовом решении загнать считай в 0.

vy+=gravity*0.5;
	curx+=vx0; 
	cury+=vy;
	vy+=gravity*0.5;

Но если есть формула, то почему бы по ней не посчитать?