Как вызвать функцию главного класса?

[Фенёк]

Положим есть главный класс, в нем есть функция

Main.as
 
public function doSmth(str:String):void
{
	trace(str);
}

И сторонний класс

Smth.as
 
Main.doSmth("blabla")

Почему таким образом невозможно вызвать функцию? Как это правильно сделать?

[TWETTI]

Сделайте функцию статичной. Тогда её можно будет вызвать из другого класса.

public static function doSmth():void

[-De-]

Главный класс - по сути такой же, как и остальные. Это означает, что экземпляров такого класса может быть больше одного. И у каждого свои переменные, которые, возможно, используются в функции doSmth.
И вот потому что из записи

Main.doSmth("blabla")

- невозможно понять, функцию КАКОГО именно экземпляра вызвать - ничего подобного нет.
И эта, почитайте про клчевое слово static.

[saikspaik]

Можно передать в Smth ссылку на главный класс.

[Фенёк]

saikspaik можно по подробнее как передать ссылку на главный класс?

-De- Можно ли как-нибудь явно указать на требуемый экземпляр главного класса?
Насчет статика в курсе, но вроде как потом никаких изменений вносить нельзя. Используя статик, все так же передавть параметры в функцию?

[djyamato]

можно сделать этот "главный" класс (другой вопрос, в чем его главность в отличии от остальных) синглтоном, тогда к нему будет доступ отовсюду, НО нужно ли это в действительности...

Что Вы хотите сделать ?

[Фенёк]

у меня есть P2P чат для он-лайнового тетриса, в нем юзер-лист представлен в виде объектов, при двойном клике на которые, выбранному пользователю отправляется предложение поучаствовать в поединке.

Соответственно у меня есть главный класс, в котором написана функция отправки сообщений (они бывают разных типов) и есть класс участника, который должен отправлять сообщения при двойном клике на себя.

Пойду полистаю статью про синглтон, спасибо за информацию.

[saikspaik]

можно по подробнее как передать ссылку на главный класс?

Просто в главном классе при создании Smth, передаешь ему ссылку на главный класс, конкретно вот так:

var mySmth:Smth = new Smth(this);

А потом уже в Smth пользуешься ссылкой, это будет твой главный класс.

[cleptoman]

да оставьте бедный рут в покое )..из айтема юзера по которому кликнули диспатчите событие..подписав его на это событие в руте..в нем в обработчике и отправляйте что вам нужно куда нужно.

см. EventDispatcher,Event

[djyamato]

Синглтон тут не нужен

Main

package  {
 
	import flash.display.MovieClip;
	import flash.display.Sprite;
 
	public class Main extends MovieClip 
	{
		private var userItemsSprite:Sprite=new Sprite();
		private var users:Array=new Array();
 
		public function Main() 
		{
			addChild(userItemsSprite);
 
			for(var i:int=0;i<4;i++)
			{
				var newUserItem:UserItem=new UserItem(i);
				userItemsSprite.addChild(newUserItem);
				newUserItem.x=200;
				newUserItem.y=50+i*70;
			}
			addEventListener(UserItemEvent.USERITEM_DOUBLE_CLICK,userItemDoubleClickHandler,true);
		}
 
		private function userItemDoubleClickHandler(event:UserItemEvent):void
		{
			trace("USER id "+event.messageData.data+" double click");
		}
	}
}

UserItem

package  
{
	import flash.display.MovieClip;
	import flash.events.Event;
	import flash.events.MouseEvent;
 
	public class UserItem extends MovieClip 
	{
 
		private var _id:int;
 
		public function UserItem(id:int) 
		{
			_id=id;
			addEventListener(Event.ADDED_TO_STAGE,addedToStageHandler);
		}
 
		private function addedToStageHandler(event:Event):void
		{
			buttonMode=true;
			doubleClickEnabled=true;
			addEventListener(MouseEvent.DOUBLE_CLICK,doubbleClickHandler);
		}
		private function doubbleClickHandler(event:MouseEvent):void
		{
			dispatchEvent(new UserItemEvent(UserItemEvent.USERITEM_DOUBLE_CLICK,_id));
		}
	}
}

UserItemEvent

package  
{
	import flash.events.Event;
 
	public class UserItemEvent extends Event
	{
		public var messageData:Object;
 
		public static const USERITEM_DOUBLE_CLICK:String="userItemDoubleClick";
 
 
		public function UserItemEvent(type:String,data:Object=null) 
		{
			super(type,data);
			var messObj:Object=new Object();
			messObj.data=data;
			this.messageData=messObj;
		}
	}
}