Сравнение двух массивов

[Fillini]

Здравствуйте. Не подкинете ли алгоритм сравнения двух массивов?
Т.е Есть массив А и Б. Сравниваем. Получаем массив В который содержит элементы из А не входящия в Б.
Весь гугл перерыл

 
А = ['a','b','c','d'];
Б = ['b','d'];
 
//сравниваем
 
В = ['a','c'];

[Партизан]

немного сыро... возвращает уникальные элементы первого массива не входящие во второй.

var a:Array = ["a", "b","c","z","E","g"];
var b:Array = ["a", "e","Z"];
trace(returnUnique(a,b))
 
function returnUnique(a:Array,b:Array):Array{
    var arr:Array = [];					
    for each(var i:Object in a) {
        if (b.indexOf(i) == -1) {
            arr.push(i);
        }
    }
    return arr;
}

[i.o.]

 
var a:Array = ['a','b','c','d'];
var b:Array = ['b','d'];
 
var c:Array = getSubtraction( a, b );
 
 
trace( c );
 
 
 
function getSubtraction( arrA:Array, arrB:Array ):Array
{
	var arrOut:Array = [];
 
	var _isFound:Boolean;
 
	var i:int;
	var j:int;
 
	var li:int = arrA.length;
	var lj:int = arrB.length;
 
	for( i=0; i < li; i+=1 )
	{
		_isFound = false;
 
		for( j=0; j < lj; j+=1 )
		{
			if( arrA[i] === arrB[j] )
			{
				_isFound = true;
				break;
			}
		}
 
		if( !_isFound )
		{
			arrOut.push( arrA[i] );
		}
	}
 
	return arrOut;
}

[PgeorgyV]

trace(diff([1, 2, 3, 4, 5, 6], [2, 4, 6]).join(' '));
 
public function diff(a:Array, b:Array):Array {
	var c:Array = [];
	var l:int = 0;
	var o:Object;
	for (var i:int = 0, j:int = a.length; i < j; i++) {
		o = a[i];
		if (b.indexOf(o) == -1) {
			c[l++] = o;
		}
	}
	return c;
}

[Сайлас]

Сообщение от i.o.

var arrOut:Array = [];
var _isFound:Boolean;
 
var li:int = A.length;
var lj:int = B.length;
 
var i:int;
var j:int;
 
for( i=0; i < li; i+=1 )
{
    _isFound = false;
 
    for( j=0; j < lj; j+=1 )
    {
          if( А[i] === B[j] )
          {
               _isFound = true;
               break;
          }
    }
 
    if( !_isFound )
    {
         arrOut.push( A[i] );
    }
}
 
trace( arrOut );

Можно написать более оптимальный алгоритм, если массивы будут отсортированы, кстати.

function returnUnique(a:Array,b:Array):Array{
    var arr:Array = [];					
    for each(var i:Object in a) {
        if (b.indexOf(i) == -1) {
            arr.push(i);
        }
    }
    return arr;
}

А этот код никак не поддержит дублирующиеся элементы, а если дублирующиеся элементы не нужны, то тогда лучше объект использовать - поиск по ключу наамного быстрее

[i.o.]

Можно написать более оптимальный алгоритм, если массивы будут отсортированы, кстати.

можно, тогда j будет просто начинаться не с нуля, а с i

[Партизан]

Сообщение от Сайлас

А этот код никак не поддержит дублирующиеся элементы

Если я все правильно понял из задачи топикстартера, именно это и требовалось

[Сайлас]

Сообщение от Партизан

Если я все правильно понял из задачи топикстартера, именно это и требовалось

Ну тогда лучше не массивы, а объекты использовать...

[silin]

var a:Array = ["a", "b","c","z","E","g"];
var b:Array = ["a", "e","Z"];
 
var noMatch:Function = function(element:*, index:int, arr:Array):Boolean
{
	return (this as Array).indexOf(element) < 0;
}
 
var difArr:Array = a.filter(noMatch, b);
trace( "difArr : " + difArr );

[Fillini]

Спасибо. Все работает. Да именно не дублирующиеся. Использую алгоритм партизана.