как использовать URLStream для загрузки изображения ?

[Vishapakahr]

я нашел в Инете пример этой задачи написанный в флексе http://onflex.org/flexapps/applicati...iew/index.html , но там используется
некий imageCanvas компонент ...

короче если несложно то пожалуйста кто может написать анологичный способ
AS3 кода , который сработывает на флеше пусть напишет его .

например в локалхосте у меня есть изображение image.jpg , и хочу чтобы он загрузился постепенно , как в html е .

[Мечтатель]

подумаешь...Меняем его на DisplayObjectContainer и все ништяк.

package 
{
	/*BASED ON 
	* http://onflex.org/flexapps/applicati...iew/index.html 
	* CODE EXAMPLE
	* Flash modification by LOST'овчанин
	*/
 
	import flash.net.URLStream;
	import flash.net.URLRequest;
	import flash.utils.*;
	import flash.display.*;
	import flash.events.*;
 
 
	public class ProgressiveLoader
	{
 
		private var loader:Loader;
 
		private var imageStream:URLStream;
 
		private var imageData:ByteArray;
 
		private var mainSprite:Sprite;
 
 
 
 
 
        /**
		 * Constructor for ProgressiveLoader class
		 *
		 * @Does not request arguments
		 * @langversion ActionScript 3.0
		 * @playerversion Flash 10.0
		 */		
 
		public function ProgressiveLoader():void
		{
 
			mainSprite=new Sprite();
			mainSprite.addEventListener(Event.RENDER, renderListener);
 
			imageStream = new URLStream();
			imageStream.addEventListener( ProgressEvent.PROGRESS , imageStreamProgress );
			imageStream.addEventListener( Event.COMPLETE , imageStreamComplete );
 
			loader = new Loader();
 
			mainSprite.addChild( loader );
		}
 
		private function imageStreamProgress( event:Event ):void
		{
			if (imageStream.bytesAvailable==0)
			{
				return;
			}
			this.processImageData();
		}
 
		private function imageStreamComplete( event:Event ):void
		{
			if (imageStream.connected)
			{
				imageStream.close();
			}
 
 
			mainSprite.stage.invalidate();
		}
 
		private function processImageData():void
		{
			if (imageStream.connected)
			{
				imageStream.readBytes( imageData , imageData.length );
			}
 
			loader.unload();
 
			loader.loadBytes( imageData );
		}
 
		private function renderListener(e:Event):void
		{
			loader.unload();
 
			loader.loadBytes( imageData );
		}
 
		/**
		 * Start image loading 
		 *
		 * @param input The URL path to image
		 * @langversion ActionScript 3.0
		 * @playerversion Flash 10.0
		 */		
		public function loadImage( input:String ):void
		{
			if (imageStream.connected)
			{
				imageStream.close();
			}
 
			imageStream.load( new URLRequest( input + '?' + getTimer() ) );
 
			loader.unload();
 
			imageData = new ByteArray();
		}
 
		public function get canvas():Sprite
		{
			return mainSprite;
		}
	}
}

[Vishapakahr]

спасибо !