Вызов setInterval () в классе.

[Волгоградец]

Привет! Друзья, помогите разобраться с такой вот ситуёвиной: в классе не работает setInterval (), а точнее не создается экземпляр другого класса.

import mx.utils.Delegate;
class LevelOne {
	private var mc:MovieClip;
	private var n:Number;
	private var interval:Number;
	private var rapid:Number = 100;

	public function LevelOne (_mc:MovieClip){
		mc = _mc;
		mc.onMouseDown = Delegate.create(this, shoot);
		mc.onMouseUp = Delegate.create(this, finish);
	}
	
	private function shoot ():Void{
		n = setInterval (create, rapid);
	}
	
	private function finish ():Void{
		clearInterval (n);
	}

	private function create ():Void{
		trace ("kkk"); //этот трэйс срабатывает
		var bul:Shot = new Shot (mc); //экземпляр на сцене не появляется
	}
}

Вот на всякий случай код класса, экземпляр которого нужно создать:

class Shot {
	
	private var missile:MovieClip;
	private var _mc:MovieClip;
	private static var a:Number = 0;

	public function Shot (mc:MovieClip){
		_mc = mc;
		a ++;
		missile = _mc.attachMovie("inst", "inst" + a, _mc.getNextHighestDepth ());
	}
}

Я думаю что это проблемы с "малопонятной" областью видимости этого самого setInterval ()...

[WindWalker]

Ты не передаёшь ссылку на объект.
Сделай так:

n = setInterval (this, "create", rapid);

[etc]

setInterval(this, 'create', rapid);

[Волгоградец]

Спасибо!
А на что указывает слово this?

[etc]

На экземпляр класса, то бишь на экземпляр LevelOne.

[WindWalker]

На текущий объект. В данном случае - на объект класса LevelOne.

Функция-то у тебя вызывалась, и конструктор вызывался, то вот поле mc не находилось.

Попробуй в своём первоначальном варианте написать:

private function create ():Void{
           trace ("this: "+this);
           trace ("this.mc: "+this.mc);
           trace ("mc: "+mc);
	var bul:Shot = new Shot (mc); 
}

И увидишь сплошные undefined.
Затем поменяй setInterval так, как было сказано выше, и обнаружишь, что this теперь показывается как [Object], а this.mc и mc - это синонимы.

[Волгоградец]

Теперь все ясно. WindWalker, __etc, большое спасибо!