не закрашивает цветом

[Mr. Fixit]

В чем проблема? Почему не закрашивает цвет?

class Valve {
	//properties
	var const:Number = -250;
	var myColor:Color;
	var myTransform:Object;
	//constructor
	function Valve (_mc:MovieClip) {
		//definite
		var myColor:Color = new Color (_mc.lamp);
		var myTransform:Object = myColor.getTransform ();
		//processes
		_mc.onRollOver = function () {
			myTransform = {rb:10, bb:const, gb:const};
			myColor.setTransform (myTransform);
		};
		_mc.onRollOut = _mc.onReleaseOutside=function () {
			myTransform = {rb:50, bb:0, gb:0};
			myColor.setTransform (myTransform);
		};
	}
}

[Wolsh]

Вопрос неправильно сформулирован. Без классовой обертки все перекрашивается.
Так что вопрос наверно почему не работает конструктор
Я своим скудным умом в этой области подозреваю что lamp в данном случае не может стать колором, так как не определен тип.

[Mr. Fixit]

lamp - это объект, который находится в _mc.
Как-то непонятно, в чем именно проблема.
Ну что буду разбираться...

[etc]

На правах оффтопа: классы так не пишут.

[Mr. Fixit]

а как тогда???

[Kikasso]

Примерно так:

import mx.utils.Delegate;
class Valve {
//properties
private var const:Number = -250;
private var myColor:Color;
private var myOutTransform:Object;
private var myOverTransform:Object;

//constructor
function Valve (_mc:MovieClip) {
	
	myColor = new Color (_mc.lamp);
	myOutTransform = myColor.getTransform ();
	myOverTransform = {rb:10, bb:const, gb:const};
	_mc.onRollOver = Delegate.create( this, mcOnRollOver );
	_mc.onRollOut = _mc.onReleaseOutside = Delegate.create( this, mcOnRollOut );
}
	
private function mcOnRollOver():Void{
	myColor.setTransform (myOverTransform);
};
private function mcOnRollOut():Void{
	myColor.setTransform (myOutTransform);
};
}

Но кстати Color устарел , и его есть чем заменить.

[Mr. Fixit]

Kikasso
Спасибо.