можно ли сделать кнопку...

[shaltay]

Не подскажете, как сделать кнопку, что-б зона наведения и зона нажима были в разных местах.
Поясняю: кнопка, наводим на нее, из нее вылезает вниз надпись типа "enter". Надо опустить мышку на enter и нажать... Есть такая возможность?

[Хемуль]

Я предлагаю это сделать не кнопками, а мувиклипами. Создаём мувиклип для нашей кнопки с двумя кадрами для состояний out и over. Помечаем кадры метками "out" и "over". Создаём мувиклип для выпадающей надписи с аналогичными двумя кадрами для состояний out и over. Далее назначаем мувиклипу кнопки в библиотеке Linkage id - "button", а мувиклипу выпадающей надписи - "dropDown". В кадре главного таймлайна пишем:

this.attachMovie("button", "button", this.getNextHighestDepth(), {_x:100, _y:100});
this.button.gotoAndStop("out");

this.button.onRollOver = function()
{
	this.gotoAndStop("over");
	var dropDownClip:MovieClip = this.attachMovie("dropDown", "dropDown", this.getNextHighestDepth(), {_x:0, _y:this._height});
	dropDownClip.gotoAndStop("out");
	dropDownClip.onRollOver = function()
	{
		this.gotoAndStop("over");
	};
	dropDownClip.onRollOut = function()
	{
		this.gotoAndStop("out");
	};	
}

this.button.onRollOut = function()
{
	this.gotoAndStop("out");
	this.dropDown.removeMovieClip();
}

this.button.onMouseMove = function()
{
	if (this.dropDown.hitTest(this._parent._xmouse, this._parent._ymouse, true))
	{
		this.dropDown.gotoAndStop("over");
	}
	else
	{
		this.dropDown.gotoAndStop("out");
	}
}

this.button.onPress = function()
{
	if (this.dropDown.hitTest(this._parent._xmouse, this._parent._ymouse, true))
	{
		trace("Pressed!"); // Тут идут действия, которые выполняются при нажатии выпавшей надписи
	}
}

Как видите, поскольку надпись присоединяется внутрь мувиклипа кнопки на сцене, используется функция hitTest для проверки, находится ли курсор мыши над нашей надписью или нет. Есть и другие способы сделать подобное. Я представил такой...
Этот пример прикрепляю...

[shaltay]

огромное спасибо)). Я почти все понял)). Попрробую сам добиться такого же)))