getter и массив

[Akopalipsis]

Один раз я уже сталкивался с идентичной ситуацией, но это было в самом начале моего знакомства и получив образный ответ, я даже сейчас его не понимаю, по этому и спрашиваю повторно. Как работает сеттер?
вот код для примера:

package  
{
	public class ClassGetSet 
	{
		private var _string:Vector.<Array> = new Vector.<Array>;
 
		public function set text(value:Vector.<Array>):void 
		{
			trace('setter');
			this._string = value;
		}
		public function get text():Vector.<Array>
		{ 
			trace('getter');
			return this._string;
		}
 
 
	}
 
}

var getSet:ClassGetSet = new ClassGetSet();
getSet.text.push(['zzz']);

Почему в таком виде сеттер не срабатывает? Ведь значение ему поступают из параметров и уже потом в теле
присваиваются. Значит тело срабатывает.

[Wolsh]

getSet.text.push('zzz');

У Вас же Вектор стрингов, а не массивов? Так почему Вы добавляете в него массив?

[Akopalipsis]

У Вас же Вектор стрингов, а не массивов?

я ошибся, исправил.

[Wolsh]

У меня все работает.

[Akopalipsis]

У меня все работает.

Работает и у меня, то есть значение присваивается, но мне хотелось бы узнать, почему трейс в теле сеттера не срабатывает.

[olexandr]

		private var _text:String = "";
		private var _arr:Array = [];
 
		public function Main():void {
			text += "1";
			arr.push(1);
		}
 
		public function get text():String {
			trace( "get string" );
			return _text;
		}
 
		public function set text(value:String):void {
			trace( "set string");
			_text = value;
		}
 
		public function get arr():Array {
			trace( "get array" );
			return _arr;
		}
 
		public function set arr(value:Array):void {
			trace( "set array");
			_arr = value;
		}

Как и положено, выводится:

get string
set string
get array

То есть, при обращении к объекту вызывается геттер, а при записи в него вызывается сеттер

[Wolsh]

мне хотелось бы узнать, почему трейс в теле сеттера не срабатывает.

Потому что сеттер нигде не вызывается.
getSet.text /*получили ссылку на Вектор*/.push(['zzz']) /*Добавили В ЭТОТ ВЕКТОР новый элемент*/;
Где Вы видите вызов сеттера set text() задающего НОВЫЙ Вектор?

[Akopalipsis]

Не совсем значит до сего дня я понимал, что такое сеттер. Спасибо Вам за помощь!