Как создать сетку?

[Digital]

Как создать сетку 10на10 пикселей ПРОГРАмМНО? Циклом?
Нужна сетка, на всю рабочую область

[zomkoner]

Вы имеете ввиду нарисовать сетку обычными линиями?
P.S я просто пока что зеленый, может я что то не до понимаю...

[Digital]

Да, да обычными линиями. Просто все мои варианты какие-то масивные) Хотелось бы что-то по короче

[zomkoner]

Сейчас я попробую создать! Не знаю подойдет ли тебе мой вариант.

Добавлено через 10 минут

import flash.display.Sprite;
import flash.display.Shape;
 
var conteiner:Sprite = new Sprite();
var xMax:int = 100;
var yMax:int = 100;
var setka:int = 10;
 
addChild(conteiner);
addSetka(xMax, yMax, setka);
 
function addSetka(xM:int, yM:int, size:int):void{
	var lineX:int = (xM / size);
	var lineY:int = (yM / size);
	for (var i:int = 0; i<lineX; i++){
		var kordX:int = i * size;
		var shape:Shape = new Shape();
		shape.graphics.lineStyle(1, 0x000000);
		shape.graphics.moveTo(kordX, 0);
		shape.graphics.lineTo(kordX, yM);
		conteiner.addChild(shape);	
	}
	for (var i:int = 0; i<lineY; i++){
		var kordY:int = i * size;
		var shape:Shape = new Shape();
		shape.graphics.lineStyle(1, 0x000000);
		shape.graphics.moveTo(0, kordY);
		shape.graphics.lineTo(xM, kordY);
		conteiner.addChild(shape);	
	}
}

Вот. Не знаю подойдет ли тебе это или нет.

[Digital]

Немного короче чем у меня. Спасибо) НО
Монтажный кадр 1, слой "Слой 1", кадр 1, строка 25 Warning: 3596: Повторное определение переменной.

[zomkoner]

import flash.display.Sprite;
import flash.display.Shape;
 
var conteiner:Sprite = new Sprite();
var xMax:int = 100;
var yMax:int = 100;
var setka:int = 10;
 
addChild(conteiner);
addSetka(xMax, yMax, setka);
 
function addSetka(xM:int, yM:int, size:int):void{
	var lineX:int = (xM / size);
	var lineY:int = (yM / size);
	for (var i:int = 0; i<lineX; i++){
		var kordX:int = i * size;
		var shape:Shape = new Shape();
		shape.graphics.lineStyle(1, 0x000000);
		shape.graphics.moveTo(kordX, 0);
		shape.graphics.lineTo(kordX, yM);
		conteiner.addChild(shape);	
	}
	for (var ii:int = 0; ii<lineY; ii++){
		var kordY:int = ii * size;
		var shape2:Shape = new Shape();
		shape2.graphics.lineStyle(1, 0x000000);
		shape2.graphics.moveTo(0, kordY);
		shape2.graphics.lineTo(xM, kordY);
		conteiner.addChild(shape2);	
	}
}

лучше вот так, а то ошибки выдаёт о повторном создании...

Добавлено через 59 секунд
Я просто сразу не заметил!

Добавлено через 4 минуты
PS Можешь убрать var xMax:int = 100;
var yMax:int = 100;
var setka:int = 10; и написать addSetka(100, 100, 10);
ещё короче станет =)

[Digital]

Ооо) Это другое дело) Ещё бы сетка не обрывалась...

Добавлено через 1 минуту
for (var i:int = 0; i<lineX+1; i++){
Так лучше, сетка выходит законченная

Добавлено через 2 минуты
Огромное вам спасибо) Очень выручили)

[zomkoner]

Да не за что! Мне самому это полезно! В подписи сказано почему...=)

[caseyryan]

package 
{
	import flash.display.Sprite;
 
 
	public class Main extends Sprite {
 
		private var _cell:		int = 10;
		private var _numCellsW:	int = 0;
		private var _numCellsH:	int = 0;
 
		public function Main() {
			_numCellsW 	= stage.stageWidth / _cell;
			_numCellsH	= stage.stageHeight / _cell;
			graphics.lineStyle(1, 0x000000);
			for (var i:int = 0; i < _numCellsH; i++) {
				for (var j:int = 0; j < _numCellsW; j++) {
					graphics.drawRect(j * _cell, i * _cell, _cell, _cell);
				}
			}
			graphics.endFill();
		}
	}
}

ну или если в кадре, то

var cell:int = 10;
var numCellsW:int = stage.stageWidth / cell;
var numCellsH:int = stage.stageHeight / cell;
graphics.lineStyle(1, 0x000000);
for (var i:int = 0; i < numCellsH; i++) {
	for (var j:int = 0; j < numCellsW; j++) {
		graphics.drawRect(j * cell, i * cell, cell, cell);
	}
}
graphics.endFill();

п.с.

лучше вот так, а то ошибки выдаёт о повторном создании...

Не лучше ли тогда так:

for (i = 0; i < lineY; i++)

переменная i уже определена, незачем ее определять повторно

[zomkoner]

Да, согласен! Я что то даже об этом и не подумал! Так будет намного лучше!