actionscript и реестр ПК

[JOGER]

Здравствуйте! Уважаемые форумчане, помогите советом и разъясните:
Можно ли через экшнскрипт записать информацию в реестр компьютера? Для простоты понимания мне нужно сделать чтобы при запуске файла стартовал таймер и показывалось изображение 5 минут, а если прошло 5 минут то появлялось сообщение к примеру "Hello". Только проблема в том, что мне нужно чтобы при закрытии файла 5 минут продолжали тикать. И если открыть файл спустя 5 минут, то уже было написано "Hello". Возможно ли так сделать?

Или есть какой-то более простой способ чем использование реестра?

Заранее спасибо!!!

[GBee]

SharedObject
А в реестр наверно через аир.

[JOGER]

прошу поясни, а то я совсем новичок в этом деле..

[Inet_PC]

Вам нужно было просто поискать, либо здесь на форуме, либо в гугле, и Вы бы точно нашли это.

[JOGER]

В этом то и проблема, если б я знал что искать..

а как примерно это исполнить, можете написать? так сказать без высоких материй..

[silin]

public class Main extends Sprite 
{
	private var start:Number;
	private var label:TextField = new TextField();
	private var timer:Timer = new Timer(1000);
	private var so:SharedObject;
 
 
	public function Main():void 
	{
		so = SharedObject.getLocal("hello");
		//so.clear(); return;// удаление записи
 
 
		if (so.data.start)
		{
			// если есть записанное время, берем его
			start = so.data.start;
		}else
		{
			// если нет, то берем системное и его записываем
			so.data.start = start = (new Date()).getTime();
 
		}
 
		addChild(label);
		timer.addEventListener(TimerEvent.TIMER, timer_timer);
		timer.start();
	}
 
	private function timer_timer(e:TimerEvent):void 
	{
 
		var delta:Number =(new Date()).getTime() - start;
 
		if (delta < 5*6e4)
		{
			// не прошло 5 мин.
			label.text = int(delta / 6e4) + " min; " + int(1e-3*(delta % 6e4)) + " sec";
		}else
		{
			// все, привет..
			label.text = "hello";
			timer.removeEventListener(TimerEvent.TIMER, timer_timer);
 
		}
	}
 
}

[JOGER]

Сообщение от silin

public class Main extends Sprite 
{
	private var start:Number;
	private var label:TextField = new TextField();
	private var timer:Timer = new Timer(1000);
	private var so:SharedObject;
 
 
	public function Main():void 
	{
		so = SharedObject.getLocal("hello");
		//so.clear(); return;// удаление записи
 
 
		if (so.data.start)
		{
			// если есть записанное время, берем его
			start = so.data.start;
		}else
		{
			// если нет, то берем системное и его записываем
			so.data.start = start = (new Date()).getTime();
 
		}
 
		addChild(label);
		timer.addEventListener(TimerEvent.TIMER, timer_timer);
		timer.start();
	}
 
	private function timer_timer(e:TimerEvent):void 
	{
 
		var delta:Number =(new Date()).getTime() - start;
 
		if (delta < 5*6e4)
		{
			// не прошло 5 мин.
			label.text = int(delta / 6e4) + " min; " + int(1e-3*(delta % 6e4)) + " sec";
		}else
		{
			// все, привет..
			label.text = "hello";
			timer.removeEventListener(TimerEvent.TIMER, timer_timer);
 
		}
	}
 
}

вставил код, а компилятор выдал ошибку "Атрибут public может использоваться только внутри пакета. public class Main extends Sprite" как исправить это? или я что то не так делаю?(

[gagaga]

в каждом классе в доках есть примеры внизу страницы

[Inet_PC]

В этом то и проблема, если б я знал что искать..

Вам же во втором посте указали что искать...

[silin]

ага, вставил в кадр..
тогда

var start:Number;
var label:TextField = new TextField();
var timer:Timer = new Timer(1000);
var so:SharedObject;
 
so = SharedObject.getLocal("hello");
 
if (so.data.start)
{
	// если есть записанное время, берем его (второй и далее запуск флешки)
	start = so.data.start;
}
else
{
	// если нет , то берем системное и его записываем(первый запуск)
	so.data.start = start = (new Date()).getTime();
 
}
 
addChild(label);
timer.addEventListener(TimerEvent.TIMER, timer_timer);
timer.start();
 
function timer_timer(e:TimerEvent):void
{
 
	var delta:Number = (new Date()).getTime() - start;
 
	if (delta < 5 * 6e4)
	{
		// не прошло 5 мин.
		label.text = int(delta / 6e4) + " min; " + int(1e-3 * (delta % 6e4)) + " sec";
	}
	else
	{
		// все, привет..
		label.text = "hello";
		timer.removeEventListener(TimerEvent.TIMER, timer_timer);
 
	}
}