вызвать функцию дочернего класса

[heartless]

вообщем есть первый класс

 
	public class SpriteExt extends Sprite
	{
 
		public function SpriteExt(myAttr:Object = null)
		{
			if (this.stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}
 
		protected function init(e:Event = null):void 
		{
			removeEventListener(Event.ADDED_TO_STAGE, init);
			trace('deleted');
		}
 
	}

и второй, его сын

 
	public class MainMenu extends SpriteExt {
 
		public function MainMenu(myAttr:Object = null) {
			super(myAttr);
		}
 
		override private function init()
		{
			trace('inited');
			super();
		}
 
	}

хочу чтобы при добавлении на сцену любого из детей SpriteExt вызывалась функция init() того класса, который сообственно создался, а не init() самого родителя SpriteExt.
Тоесть output в данном случае выглядит так:
deleted
А хотелось бы
inited
deleted

[in4core]

public class SuperClass extends Sprite{
 
   public function SuperClass()  { super(); }
   public function init():void { trace('superClass'); }
}
 
public class Extended extends SuperClass {
 
public function Extended() { super(); }
override public function init():void { trace('child of superClass') , super.init() }
}
 
Main.as
 
var child:Extended = new Extended();
child.init() // child of superClass , superClass

[Zebestov]

Автор хочет все наоборот. А так не получится.

[Wolsh]

В смысле как это не получится?

package  
{
	import flash.display.Sprite;
	import flash.events.Event;
 
	public class SpriteExt extends Sprite
	{
		public function SpriteExt(myAttr:Object = null)
		{
			if (this.stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}
 
		protected function init(e:Event = null):void 
		{
			removeEventListener(Event.ADDED_TO_STAGE, init);
			trace('deleted');
		}
	}
}

package  
{
	import flash.events.Event;
	public class MainMenu extends SpriteExt
	{
 
		public function MainMenu(myAttr:Object = null)
		{
			super(myAttr);
		}
 
		override protected function init(e:Event = null):void 
		{
			trace('inited');
			super.init(e);
		}
	}
}

[Zebestov]

Хм... я просто запутался в условии задачи. Мне показалось, что нужно из экземпляра родительского класса каким-то чудом уметь вызывать методы будущих классов, расширяющих данный.

[heartless]

да, спасибо Wolsh'у, все работает