Угол и перемещение объекта. €

[coffee2espresso]

Здравствуйте, у меня такой вопрос. Допустим я хочу переместить объект из точки (0, 0) в точку (100, 300) отображая это все на каждом энтерФрейм. Каким образом это можно реализовать? Я просто слаб в геометрии. Как задать угол и как его узнать? Какие координаты задавать объектам на каждом энтерФрейме? Прошу помочь разобраться.

[goodguy]

Math.cos() для координат по оси x, Math.sin() по y, угол между двумя точками Math.atan2()

[i.o.]

Вектор, и не надо никаких углов.

[DaFive]

Ну уж если совсем с геометрией никак - твином перемещать можно. Только время для X и для Y сделать одинаковое, чтобы не получилось, что по X уже доехали, а по Y еще едем.

[goodguy]

i.o., вектору тоже надо расчитать направление. В итоге получится тоже самое.

[windrunner31]

Не знаю,как использовать вектора,но вот как использовать "Полярные координаты",они дадут вам то,что нужно!
Пусть obj1 - ваш обьект,который надо двигать,"a" - угол,на который надо двигать,x2 - конечный x,y2 - конечный y,s - Скорость(Посчитаете ее сами,т.к она зависит от того,за какое время обьект должен доехать до конца)

var x1:Number = obj1.x;
var y1:Number = obj1.y
var a:Number = 57.29577957855229 * Math.atan2(y2 - y1, x2 - x1) // Формула нахождения угла
obj1.x += s * Math.cos(a * 0.017453292519943295);
obj1.y += s * Math.sin(a * 0.017453292519943295);

Все,это даст тебе движение в нужном направлении.

[i.o.]

i.o., вектору тоже надо расчитать направление. В итоге получится тоже самое.

Нет не то же самое. Синусы и косинусы рассчитывать не нужно.
vec = end - start; - вот и все
Если нужно привести к единичному, то
vec.normalize(1.0);
где vec.x - косинус, а vec.y - синус. При чем явно они нигде не вычисляются.

А конкретно по теме, вот (тут не то что синусов нет, даже квадратные корни не присутствуют. И зовется все это - линейная интерполяция. Твиновая функция sinInOut не в счет):

var startPoint:Point = new Point(0, 0);
var endPoint:Point = new Point(300, 300);
var currProgress:Number = 0.0;
var startTime:Number = getTimer() + 500;
var endTime:Number = startTime + 2000;
 
this.addEventListener(Event.ENTER_FRAME, this.onEnterFrame);
 
 
function onEnterFrame( e:Event ) : void
{
	var currProgress:Number = (getTimer() - startTime) / (endTime - startTime) ;
 
	if (currProgress < 0.0)
		currProgress = 0.0;
 
	if (currProgress > 1.0)
		currProgress = 1.0;
 
	var currPos:Point = calcPos( startPoint, endPoint, sinInOut(currProgress) );
 
	mc.x = currPos.x;
	mc.y = currPos.y;
}
 
function calcPos( start:Point, end:Point, progress:Number=0.0/*[0..1]*/ ) : Point
{
	return new Point( start.x + progress * (end.x - start.x),
	                  start.y + progress * (end.y - start.y) );
}
 
function sinInOut( v:Number ) : Number
{
	return 0.5 + 0.5 * Math.sin(Math.PI * (v - 0.5));
}

[goodguy]

где vec.x - косинус, а vec.y - синус. При чем явно они нигде не вычисляются.

Разве что в своем коде не будут вычисляться. Но будут в классе вектора.

[i.o.]

Разве что в своем коде не будут вычисляться. Но будут в классе вектора.

Т.е вы хотите сказать, что в функции normalize будут вызываться такие функции как Math.sin / Math.cos и Math.atan2?

[gloomyBrain]

goodguy, не будут. Нормализация вектора - это деление каждой из его координат на длину вектора. То есть примерно так:

var vec:Point = new Point(12, 18);
var vecLength:Number = Math.sqrt(vec.x * vec.x + vec.y * vec.y);
 
var normalizedVec: = new Point();
normalizedVec.x = vec.x / vecLength;
normalizedVec.y = vec.y / vecLength;

синусов и косинусов тут нет