Не отображается таймер в часах

[reNiks]

Здравствуйте! Написал таймер но он какой то кривой получился:

package ru.RainbowAdventure
{
 
    import flash.display.Sprite;
    import flash.display.MovieClip;
    import flash.utils.Timer;
    import flash.events.TimerEvent;
    import flash.events.Event;
 
 
    public class Game extends Sprite
    {
        public static var time:MovieClip;
        public static var score:MovieClip;
        public static var picture:MovieClip;
        public static var timer:MovieClip;
 
        var minutes:Number = 0;//вводим переменную - минуты
        var seconds:Number = 0;//вводим переменную - секунды
        var primer5:Timer = new Timer(1000);
 
        public function Game()
        {
            addEventListener(Event.ADDED_TO_STAGE, init);
 
        }
        private function init(event:Event):void
        {
            removeEventListener(Event.ADDED_TO_STAGE, init);
            addTimer();
            timer.text = "0:0";
            primer5.addEventListener(TimerEvent.TIMER, timerA);
            primer5.start();
 
            trace("Game initialized...");
        }
        private function addTimer():void
        {
 
            timer = new Tame_txt;
            timer.x = 220;
            timer.y = 500;
            timer.gotoAndStop(1);
            addChild(timer);
            trace("Timer initialized...");
 
 
        }
        public function timerA(event:TimerEvent):void
        {
            seconds++;
            if (seconds > 59)
            {
                seconds = 0;
                minutes++;
            }
 
            //секунды и минуты переводятся в строку. между ними будет стоять двоеточие
            timer.text = String(minutes + ":" + seconds);
            trace ("timer.!>!>!");
        }
 
 
 
 
    }
 
}

после трейса показывает что таймер сам идет, но он не отбражается. Помогите пожалуйста.

[tsarapkabel]

?

public static var timer:Tame_txt;
...
timer = new Tame_txt;

[reNiks]

Сообщение от tsarapkabel

?
Код AS3:
public static var timer:Tame_txt;
...
timer = new Tame_txt;

извините немного Вас не понял. Это то что и как надо исправить в коде? Если так то все равно не отображается

[tsarapkabel]

Не знаю что у Вас происходит в классе Tame_txt, вот работающий таймер, вывод в textField:

package {
 
	import flash.display.Sprite;
	import flash.display.MovieClip;
	import flash.events.TimerEvent;
	import flash.events.Event;
	import flash.text.*;
	import flash.utils.Timer;
 
	public class Game extends Sprite {
 
		private var timerText:TextField;
		private var minutes:uint = 0;//вводим переменную - минуты
		private var seconds:uint = 0;//вводим переменную - секунды
		private var primer5:Timer = new Timer(1000);
 
		public function Game() {
			addEventListener(Event.ADDED_TO_STAGE, init);
		}
 
		private function init(event:Event):void {
			removeEventListener(Event.ADDED_TO_STAGE, init);
			trace("Game initialized...");
			timerText = new TextField();
			timerText.text = "0:0";
			primer5.addEventListener(TimerEvent.TIMER, timerA);
			primer5.start();
			addTimer();
		}
 
		private function addTimer():void {
			trace("Timer initialized...");
			timerText.x = 220;
			timerText.y = 500;
			addChild(timerText);
		}
 
		public function timerA(event:TimerEvent):void {
			seconds++;
			if (seconds > 59) {
				seconds = 0;
				minutes++;
			}
 
			//секунды и минуты переводятся в строку. между ними будет стоять двоеточие
			timerText.text = String(minutes + ":" + seconds);
			trace ("timer.!>!>!");
		}
	}
}

[reNiks]

Tame_txt это класс мувиКлипа, в котором создано динамическое текстовое поле для таймера. На сколько я понял таймер не показывает потому что нет ссылки именно на текстовое поле. Извините за мою упертость, но нужно что бы отображалось именно в Tame_txt. Это поросто мувиклип в создано динамическое текстовое поле и больше ничего нету.

[Anton Riot]

если Tame_txt - это класс мувиКлипа. то как это так вы обращаетесь к timer.text?
откуда у мувиклива поле text?

[tsarapkabel]

Почему бы и нет. В библиотеке MovieClip, имя класса Asdfghjkl. В этом самом MovieClip'е текстовое поле с именем экземпляра textInside.

package {
 
	import flash.display.Sprite;
	import flash.events.TimerEvent;
	import flash.events.Event;
	import flash.text.TextField;
	import flash.utils.Timer;
 
	public class Game extends Sprite {
 
		private var minutes:uint = 0;
		private var seconds:uint = 0;
		private var primer5:Timer = new Timer(1000);
		private var myTimerBox:Asdfghjkl; //инициализировали класс
 
		public function Game() {
			addEventListener(Event.ADDED_TO_STAGE, init);
		}
 
		private function init(e:Event):void {
			removeEventListener(Event.ADDED_TO_STAGE, init);
			trace("Game initialized...");
			primer5.addEventListener(TimerEvent.TIMER, timerA);
			primer5.start();
			myTimerBox = new Asdfghjkl(); //создали экземплярчик
			addTimer();
		}
 
		private function addTimer():void {
			trace("Timer initialized...");
			myTimerBox.x = myTimerBox.y = 50;
			addChild(myTimerBox);
		}
 
		public function timerA(event:TimerEvent):void {
			trace ("timer.!>!>!");
			seconds++;
			if (seconds > 59) {
				seconds = 0;
				minutes++;
			}
			myTimerBox.textInside.text = (minutes + ":" + seconds);
		}
	}
}

[Vektor]

timer.text String(minutes + ":" + seconds);

timer.имя_text.text.
имя_text - задаётся в свойствах.

[reNiks]

спасибо огромное