DataGrid выделить жирным ячейку

[max_oil]

Кто может подсказать как выделить жирным ячейку?
формат <b> не получается.. может как то еще можно?

private function labelFormatter(data:Object, column:DataGridColumn):String {
	if (column.headerText == "Message") {
		if (data.IsReaded == "false") {
			trace("isReaded");
			return "<b>"+data[column.dataField]+"</b>";
		}
	}
	return data[column.dataField];
}

Добавлено через 2 минуты
пытаюсь делать через labelFunction

[ERrorMAKros]

По моему в этом случае лучше писать свой cellRenderer.

[max_oil]

а из cellRenderer есть доступ к конкретной ячейке?

[ERrorMAKros]

А как это все в итоге должно быть, я так понимаю, что есть таблица с N строками и N столбцами. При нажатии мышкой на любую ячейку текст должен стать жирным?

[max_oil]

ага действительно там тоже есть свойтсво data и по сути нужно написать такой же код единственно не разобрался как применить это только к конкретному столбцу?

override protected function drawLayout():void {
		if (data.IsReaded == "false") {
			var tf:TextFormat = new TextFormat();
			tf.bold = true;
			textField.setTextFormat(tf);
		}
		super.drawLayout();
	}

это функция из cellRenderer которая красит всю строку.. (в прниципе меня это устраивает, но из интересно интересно можно ли узнать еще и к какому столбцу я применяю формат?)

[ERrorMAKros]

Решил средствами CellRenderer
dataGridCellExample.fla

import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
import fl.events.ListEvent;
 
var xml:XML=<tickets>
<item>
<ID>231</ID>
<Status>Modified</Status>
</item>
<item>
<ID>232</ID>
<Status>Confirmed</Status>
</item>
<item>
<ID>233</ID>
<Status>Pending</Status>
</item>
</tickets>;
dataG.dataProvider=new DataProvider(xml);
dataG.columns[1].cellRenderer=customRender;

И customRender.as

package {
	import fl.controls.listClasses.CellRenderer;
	import flash.text.TextFormat;
	import fl.controls.listClasses.ListData;
	import fl.controls.DataGrid;
	import fl.controls.dataGridClasses.DataGridColumn;
	import fl.data.DataProvider;
	import fl.events.ListEvent;
 
	public class customRender extends CellRenderer {
		public function customRender():void {
 
		}
		public override function set listData(value:ListData):void {
			var SaveIndex:Number = (value.owner as DataGrid).selectedIndex;
			var tf:TextFormat = new TextFormat();
 
			if (SaveIndex==value.index) {
				tf.bold=true;
				tf.color=0xFF0000;
			} else {
				tf.bold=false;
				tf.color=0x0000FF;
			}
			setStyle("textFormat",tf);
			super.listData=value;
 
		}
	}
}

Все можно скачать тут: http://filebox.od.ua/?file=dc34ae342...03fb7334e8e549