Помогите, пожалуйста, найти ошибку в коде.

[goldlider]

Имеется такая задача: даны два текстовых поля и две кнопки. Вводим в поле vvod какое-нибудь число. При нажатии на кнопку btn1 идет проверка есть ли данное число в массиве. Ответ записывается в поле otvet. Кнопка btn2 служит для очистки поля otvet.
Вот AS-код:

var massiv:Array = ["123000", "123456", "908070"];
 
btn1.addEventListener(MouseEvent.CLICK, proverka);
 
function proverka(event:MouseEvent):void
{
	for (var i:int = 0; i < massiv.length; i++)
	{
		if (massiv[i] == vvod.text)
		{
			otvet.text = "Верный пароль";
		}
                else
		{
			otvet.text = "Неверный пароль"
		}
 
	}
}
 
btn2.addEventListener(MouseEvent.CLICK, cleaning);
 
function cleaning(event:MouseEvent):void
{
	otvet.text = "";
}

Собственно проблема заключается в том, что при вводе в поле vvod верного числа, постоянно выводит ответ "Неверный пароль". Вроде бы, код верный.

[Bgg]

А что в trace'е пишется?

function proverka(event:MouseEvent):void
{
	for (var i:int = 0; i < massiv.length; i++)
	{
		if (massiv[i] == vvod.text)
		{
			otvet.text = "Верный пароль";
			return;//зачем дальше искать?
		}
                else
		{
			trace("massiv:" + massiv[i] + " vvod:" + vvod.text);
			otvet.text = "Неверный пароль"
		}
 
	}
}

[goldlider]

Bgg, мне не понятно, для чего здесь нужен return. У меня же функция ничего не возращает.

[leofit]

function proverka(event:MouseEvent):void
{
	for each(var val in massiv)
	{
		if (val == vvod.text)
		{
			otvet.text = "Верный пароль";
                        return;
		}
 	}
       otvet.text = "Неверный пароль";
 
}

[cleptoman]

голдлидер, return прерывает цикл и возвращает undefined

[goldlider]

cleptoman, т.е. return останавливает цикл, если найдено верное число, не проверяя далее весь массив.

[Psycho Tiger]

Сообщение от cleptoman

голдлидер, return прерывает цикл и возвращает undefined

Не совсем.

		private function myFunction():void
		{
			return undefined; //compile error :(
		}

Если глянуть опкод для return; мы увидим returnvoid. Это не undefined, компилятор говоря "must be undefined" при попытке вернуть что то из void метода/функции не имеет ввиду ключевое слово undefined.

[cleptoman]

я к тому что, у bgg мысль правильная.
лучше вынесите проверку в отдельный метод и возвращайте булево

function proverka(event:MouseEvent):void
{
otvet.text = (_isRightPass()) ? "Верный пароль" : "Неверный пароль"
}
 
private function _isRightPass():Boolean{
      for each(var val in massiv)	{
		if (val == vvod.text)		{
                        return true;
		}
                return false;
 	}
 
}

эдаким макаром мы от лишних итераций цикла уходим

[leofit]

cleptoman, логическая ошибка

 
private function _isRightPass():Boolean{
      for each(var val in massiv)	{
		if (val == vvod.text)		{
                        return true;
		}
              //  return false;
 	}
        return false;
 
}

[cleptoman]

я вот к чему:

function getVoid():void{return };
trace(getVoid())

Добавлено через 1 минуту
leofit, да, конечно..с копипастами, не провирил )