Синтаксис неведомый мне

[nikewist]

Всем добрый день! Недавно изучал скролл многоуважаемого Walsh и наткнулся на строки, которые привели меня в некоторое замешательство, потому как я такого синтаксиса еще не видел. Объясните кто-нибудь, пожалуйста, что это такое и с чем его едят

pimp._y = pimp._y < pimp_start ? pimp_start : pimp._y > pimp_stop ? pimp_stop : pimp._y;

И второе, там же есть еще один интересный момент. В хэлпе сказано русским по белому:

someListener.onMouseMove = function() { ... };

А у Walsh вот так. Это как? Там же справа должна быть функция!

this.onMouseMove = scrolling;

[VVall]

http://ru.wikipedia.org/wiki/Тернарн...овная_операция

[alexcon314]

1.Буквальный "перевод" строки

pimp._y = pimp._y < pimp_start ? pimp_start : pimp._y > pimp_stop ? pimp_stop : pimp._y;

если ничего ненапутал такой:

if (pimp._y < pimp_start) {
	pimp._y = pimp_start;
} else {
	if (pimp._y > pimp_stop) {
		pimp._y = pimp_stop;
	} else {
		pimp._y = pimp._y;
	}
}

более просто

a = c < b ? c : b;
//что эквивалентно
if (c < b) {
	a = c;
} else {
	a = b;
}

2. В примере из хэлпа справа стоит анонимная функция.
у Wolsh'a справа стоит ссылка на функцию, которая была объявлена где-то в коде как

function scrolling(){
...
}

или как

scrolling = function(){
...
}

Ссылками вцелом удобнее пользоваться.
Вобщем, такой вот стиль.

[nikewist]

Спасибо Вам, добрые люди!

[Волгоградец]

Интересный вопрос. В случае одного использования тернарного оператора все понятно. Но в коде Walsh'а их два. А если их два, то выполнение идет справа налево. Как выглядит аналог if/else в таком случае?

[nikewist]

По первому вопросу более или менее ясно. Немного порылся в инете, но так и не понял зачем анонимная функция в данном примере? Почему надо писать scrolling, а не scrolling()? Тем более, что объявлялась она как

function scrolling(){
...
}

И что самое ужасное, это то, что даже если прописать scrolling(), то оно так не работает! Вообщем кипят мои мозги...

[.true]

this.onMouseMove = scrolling; == this.onMouseMove = function(){scrolling();}

прописать можно или так или так. Но. в первом случае ты подразумеваешь просто название функции, ты и так знаешь, что вызвать так можно только функцию.

А в блоке function(){

}

ты описываешь свои действия, выражения, и необязательно функции. Во втором примере можно написать более 1 выполняемой функции если нужно, в первом - только 1.

[TihelpER]

nikewist

Следующий код даёт ссылку на функцию scrolling()

mc.onPress = scrolling

Если мы пишем scrolling(), то есть со скобочками, то мы либо объявляем её:

function scrolling() {
...
}

Либо вызываем её:

if(какое либо условие) {
scrolling()
}

Когда мы пишем только название функции мы именно даём ссылку на неё.

Если более дотошно, то, грубо говоря, следующий код:

mc.onPress = scrolling;

является аналогом вот такого, возможно более привычного Вам:

mc.onPress = function() { // Событие - нажали на клип
scrolling() //вызываем функцию
}

[nikewist]

Фуууухххх...В принципе я понял. Понял, что вместо того, чтобы вызвать напрямую функцию, мы вызываем анонимную функцию, которая вызовет ту функцию, которая мне нужна. Действительно, так проще и удобнее Вероятно, я отношусь к категории товарищей, которым надо пользоваться только if...
Но если серьёзно, если мы вызываем анонимную функцию, которая фактически вызывает довольно определенную функцию, то зачем эти телодвижения, где логика, где рациональное зерно?
В чем отличие в принципе работы. В математическом смысле. Потому что если я прописываю не ссылку на функцию, а напрямую вызываю функцию, то программа не работает...А с ссылкой работает. Работает, не работает, работает, не работает...

[mooncar]

Автор, часто бывает удобнее задать для какого-то действия функцию, и ее вызывать из разных мест - например, либо по нажатию кнопки, либо по какому-то другому событию. Например.

function doIt() {  //эта функция делает полупрозрачными сто объектов mc1....mc100
	for (i = 1; i <= 100; i++) {
		_root['mc' + i]._alpha = 50;
	}
}
 
btn.onPress = doIt; //функция doIt сработает при нажатии на кнопку btn
btn.onRelease = doIt; //функция doIt сработает также при отпускании кнопки btn
 
text_tf.onChanged = doIt; //функция doIt сработает при вводе нового символа в текстовое поле text_tf
 
//постоянно проверяем изменение триггера val, если = 1, также сработает функция doIt 
this.onEnterFrame  = function() { 
  if (val == 1) {
    doIt();
  }
}

Другой пример. Назначаем обработчики onRelease для 20-ти кнопок в цикле:

function goThere () {
       _root['mc' + this.num].gotoAndPlay(50); 
}
 
for (i = 1; i <= 20; i++) {
        this['btn' + i].num = i;
	this['btn' + i].onRelease = goThere;
}
//this внутри функции goThere указывает на соответствующую кнопку, для которой данная функция работает, то есть btn1... btn20
//поэтому this.num  тут будет равно последовательно btn1.num... btn20.num, то есть 1....20

Третий пример. Меняем поведение кнопки:

function doOne () {
       trace('Делай раз!')
}
 
function doTwo () {
       trace('Делай два!')
}
 
//В одной части кода:
btn.onRelease = doOne;
....
//Где-то в другом месте, при других обстоятельствах, но для той же кнопки:
btn.onRelease = doTwo;
 
//либо:
if (val == 0) {
       btn.onRelease = doOne;
} 
else {
      btn.onRelease = doTwo;
}

При такой записи код становится гибче, удобнее для модернизации, переноса в другие места и т.д.

И еще. Поймите простую вещь - вот здесь:

btn.onPress = doIt;

в правой части не определяется никакая функция, а только для события onPress указываем ссылку на функцию doIt по ее имени.
Эта запись сродни

a = b;

То есть присваиваем одной переменной ссылку на другую.