про delegate

[Chas]

вот типичный пример, когда область видимости не такая, как хотелось бы:

class game.WinMove {
var mov:MovieClip;
	function WinMove (){
		trace ("инициализация WinMove");
		mov=_root.attachMovie ("shared_skin_move","mc_move",_root.getNextHighestDepth());
		mov.btnCancel.onPress=function (){	trace ("вызываю cancel"); this.cancel ();	}
...}
...
	function cancel (){ 
		mov._visible=false;
	}

}

а хотелось бы вызвать функцию cancel класса. Из хелпа я понял, что для передачи событию нужной области видимости можно использовать Delegate. Но все примеры в хелпе для компонентов и используют eventListener. а в моем варианте Delegete можно использовать?

[CorC]

mov.btnCancel.onPress=Delegate.create(this, cancel);

[screamge]

только сначало

import mx.utils.Delegate

[Chas]

ну import, Это понятно =)
ааа... какой кайф.а то я уже устал передавать в мувик, где происходит событие ссылку на класс, которому это событие нужно принять.
я так понял, что в AS3 этой проблемы не существет в принципе?

[etc]

В AS3 все на событийной модели и нету таких обработчиков типа onRelease = function. И вызываемые методы связаны с областью видимости класса, в котором они объявлены.

[Chas]

а как переделать с Delegate такой случай?

var cur:MovieClip=mov.defence[bodyParts[i]+"Point"];
cur.partName=bodyParts[i]; cur.move=this;
cur.onRelease = function (){ this.move.pointClicked ("defence",this.partName); }

если вызвать так

cur.onRelease=Delegate.create(this,pointClicked("defence",bodyParts[i]));

то естественно в onRelease будет вызываться РЕЗУЛЬТАТ выполенеия функции pointClicked. а
как правильно?

ЗЫ: _etc, сочувствую Вашей аське. но говорят АОЛ восстанавливала бэкап базы 11 числа, и Ваш номерочек могли восстановить. правда, возможно уже с другим паролем ;-)

[CorC]

Нет просто нужно немного класс Delegate поправить, что б параметры передавать.
Мне тут iNils недавно писал его, поищите.

[etc]

Не восстановили мой номер

Что касается Delegate, то лично я использую класс ascb.util.Proxy, выкладывал на форуме.

[Chas]

я уже нашел мод iNils'a. работает. иНилс - папа =)
если ком интересно, то вот ссылка http://www.flasher.ru/forum/showpost...63&postcount=2
на самом деле, мне кажется такие вещи надо ложить в ЧаВО.

2_etc: соболезную. ну... немецкие хакеры отдохнули 9 мая, что скажешь. даже некоторые девятки, светившиеся на форумах были убиты =(

[iNils]

Я слегка его модифицировал.

/**
 * Класс ru.inils.util.Delegate, модифицированный mx.utils.Delegate. Выполнение функции в заданной области видимости с передачей параметров.
 * 
 * @author	iNils
 * @version	1.1
 * @see		mx.utils.Delegate
 */
class ru.inils.util.Delegate extends Object {
	/**
	 * Передача событий от любого объекта к любому дрогому объекту.
	 * 
	 * @usage	public static create (obj:Object, func:Function, arg:Array) : Function
	 * @param	obj	Object - Объект, целевая область видимости.
	 * @param	func	Function - Метод, обработчик данного объекта.
	 * @param	arg	Array [дополнительный параметр] - Массив передаваемых аргументов, замещающий переменные переданные при вызове целевого метода. По умолчанию возращаются параметры переданный при вызове целевого метода.
	 * @return  Function	- Функция обработчик.
	 */
	public static function create (obj:Object, func:Function, arg:Array):Function {
		var f = function () {
			var targetTemp:Object = arguments.callee.target;
			var funcTemp:Function = arguments.callee.func;
			var argTemp:Array = null;
			if (arguments.callee.arg) {
				argTemp = arguments.callee.arg;
			} else {
				argTemp = arguments;
			}
			return funcTemp.apply (targetTemp, argTemp);
		};
		f.target = obj;
		f.func = func;
		f.arg = arg;
		return f;
	}
}

Пример

import ru.inils.util.Delegate;
function echo (s) {
	trace (s);
}
o = {};
o.func1 = Delegate.create (this, echo, [33]);
o.func2 = Delegate.create (this, echo);
o.func1 (66); //33
o.func2 (66); //66