[PainKiller]

Можно. Эмбедите во флешку шрифт(ы) таким образом:

package 
{
 
	import flash.display.MovieClip;
	import flash.system.ApplicationDomain; 
 
 
	public class Agfriquer extends MovieClip
	{
 
		[Embed(source = "AG Friquer/AGFriquerC.otf", fontName="AGFriquerC", fontStyle="normal", fontWeight="normal", mimeType="application/x-font", advancedAntiAliasing="true", embedAsCFF="false")]
		public var AGFriquerC:Class;
 
		[Embed(source = "AG Friquer/AGFriquerC-Bold.otf", fontName="AGFriquerC", fontStyle="normal", fontWeight="bold", mimeType="application/x-font", advancedAntiAliasing="true", embedAsCFF="false")]
		public var AGFriquerCBold:Class;
 
		[Embed(source = "AG Friquer/AGFriquerC-Italic.otf", fontName="AGFriquerC", fontStyle="italic", fontWeight="normal", mimeType="application/x-font", advancedAntiAliasing="true", embedAsCFF="false")]
		public var AGFriquerCItalic:Class;
 
		[Embed(source = "AG Friquer/AGFriquerC-BoldItalic.otf", fontName="AGFriquerC", fontStyle="italic", fontWeight="bold", mimeType="application/x-font", advancedAntiAliasing="true", embedAsCFF="false")]
		public var AGFriquerCBoldItalic:Class;
 
 
		public function Agfriquer()
		{
			Font.registerFont (AGFriquerC);
			Font.registerFont (AGFriquerCBold);
			Font.registerFont (AGFriquerCItalic);
			Font.registerFont (AGFriquerCBoldItalic);
			var embeddedFonts:Array = Font.enumerateFonts(false);
			for (var i : int = 0; i < embeddedFonts.length; i++)
			{
				trace(embeddedFonts[i].fontName);
				trace(embeddedFonts[i].fontType);
			}
		}
	}
 
}

Потом грузите её в ту флешку, где будете использовать шрифт таким образом:

 var fontsLoader:Loader = new Loader ();
fontsLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, fontLoaded);
fontsLoader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, onIOERROR);
var context:LoaderContext = new LoaderContext();
            context.applicationDomain = ApplicationDomain.currentDomain; 
			fontsLoader.load(new URLRequest(path), context);
 
private function fontLoaded(ev:Event):void // срабатывает при загрузке swf со шрифтом
		{
			var target:LoaderInfo = ev.target as LoaderInfo;
			var mc:MovieClip = target.content as MovieClip;
			addChild(mc);
		}
 
		private function onIOERROR(e:IOErrorEvent):void
		{
			trace("Загрузка шрифтов не удалась");
		}

и все. А вообще вам надо было воспользоваться поиском по форуму таких тем тут много.