[TihelpER]

Если Вы пишите во фрэйме то переменная tweenTime будет видна т.к. вы объявили её непосредственно во фрейме, которому будет принадлежать tween.
Аналогичного результата можно добится и в классе если объявить tweenTime в теле конструктора (хотя лучше в конструкторе не описывать действия):

import mx.transitions.Tween;
import mx.transitions.easing.*;
class MyClass {
	private var tween:Tween;
	private var ball_mc:MovieClip;
 
	public function MyClass(ball_mc:MovieClip) {
		this.ball_mc = ball_mc;
	        var tweenTime:Number = 1;
                // тут tweenTime видна
		tween = new Tween(ball_mc, "_alpha", Strong.easeIn, 100, 0, tweenTime, true);
		tween.onMotionFinished = function() {
                        // и тут должна быть видна
			trace(tweenTime);
		};
	}
 
}

Я обычно поступаю следующим образом, ссылаясь на объект (экземпляр класса), создав ссылку на него в теле функции, который будет принадлежать объект (в вашем случае в конструкторе, в котором создаётся tween):

class MyClass {
	private var tween:Tween;
        private var tweenTime:Number = 1;
	private var ball_mc:MovieClip;
 
	public function MyClass(ball_mc:MovieClip) {
                var thisObj:Object = this
		this.ball_mc = ball_mc;
                // тут tweenTime видна
		tween = new Tween(ball_mc, "_alpha", Strong.easeIn, 100, 0, tweenTime, true);
		tween.onMotionFinished = function() {
                        // и тут должна быть видна
			trace(thisObj.tweenTime);
		};
	}
}

Немного по-варварски, но всё же.

С public переменной всё то же самое. А вот статические переменные, static, будут везде видны, но они будут статические.

И больше не называйте области видимости багом, пожалуйста.