[Isaac]

Сообщение от goodguy

Нет, я имел в виду другое.

package  {
	import caurina.transitions.Tweener;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.text.TextField;
	import flash.text.TextFieldAutoSize;
	/**
	 * ...
	 * @author goodguy
	 */
	public class TextAdder extends Sprite {
 
		private var _stringToShow:		String 	= "Эта строка будет разбита и показана побуквенно";
		private var _stringContainer:	Sprite 	= new Sprite();
 
		public function TextAdder() {
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}
 
		private function init(e:Event = null):void {
			removeEventListener(Event.ADDED_TO_STAGE, init);
			addChild(_stringContainer);
 
			var lettersArray:	Array 	= _stringToShow.split("");
			var arrayLength:	int		= lettersArray.length;
			for (var i:int = 0; i < arrayLength; i++) {
				var tf:TextField	= new TextField();
				tf.autoSize			= TextFieldAutoSize.LEFT;
				tf.text				= lettersArray[i];
				tf.alpha			= 0;
				_stringContainer.addChild(tf);
				if (i > 0) {
					var previousTf:TextField = TextField(_stringContainer.getChildAt(i - 1));
					tf.x	= previousTf.x + previousTf.textWidth;
				}
				Tweener.addTween(tf, { time: 1 + i / 10,  transition: "easeInExpo", alpha: 1 } );
			}
		}
	}
}

П.с. здесь используется Caurina Tweener, но это не принципиально

Строка появляется побуквенно. Примитивный вариант

Спасибо