[cv']

Предлагаю добавить их все в массив, и массив сортировать по нужному параметру.

package 
{
	import com.greensock.easing.Quad;
	import com.greensock.TweenMax;
	import flash.display.Sprite;
	import flash.events.MouseEvent;
	import flash.utils.Dictionary;
 
	/**
	 * ...
	 * @author cv
	 */
	public class Sprites extends Sprite 
	{
		private var sprites:Array;
		private var dic:Dictionary;
 
		public function Sprites()
		{
			dic = new Dictionary();
			sprites = [];
			var container:Sprite = new Sprite();
			container.x = 
			container.y = 50;
			addChild(container);
 
			for (var i:int = 0; i < 10; i++) 
			{
				var sprite:Sprite = new Sprite();
				sprite.graphics.beginFill(Math.random() * 0xFFFFFF);
				sprite.graphics.drawRect(0, 0, 50, 50);
				sprite.y = 60 * i;
 
				var info:Object = { };
				info.sprite = sprite;
				info.id = i;
				info.num = i;
 
				sprite.addEventListener(MouseEvent.CLICK, clickHandler);
				dic[sprite] = info;
				sprites[i] = info;
 
				container.addChild(sprite);
			}
		}
 
		private function clickHandler(event:MouseEvent):void 
		{
			var info:Object = dic[event.currentTarget];
			info.num = Math.random() * 10;
			sprites.sortOn('num', Array.NUMERIC);
			for (var i:int = 0; i < sprites.length; i++) 
			{
				info = sprites[i];
				var sprite:Sprite = info.sprite;
				TweenMax.to(sprite, 0.5, { ease:Quad.easeOut, y:60 * i});
			}
		}
	}
 
}