Форум Flasher.ru - синтаксис в AS 2.0

Форум Flasher.ru (http://www.flasher.ru/forum/index.php)

- - синтаксис в AS 2.0 (http://www.flasher.ru/forum/showthread.php?t=86782)

синтаксис в AS 2.0

ранее заморачивался немного AS 1.0,седне пробило сел за AS 2.0 выстрадал вот это (сокращенный вариант):

Код:

class Movement {

        function Movement() {

        }

        static function moveBehindTheMouse(mc:MovieClip, dl:Number):Void {

                mc.onEnterFrame = function() {

                        this._x += (_xmouse - mc._x) * dl;

                        this._y += (_ymouse - mc._y) * dl;

                };

        }

}

хотелось бы Please услышать комментарии по поводу синтаксиса .Обязательно ли объявлять конструктор,типы пременных и функций? Работает все вроде и без этого.

Цитата:

Сообщение от udaaff

class Movement {

Любой класс должен наследовать Object или потомка класса Object (собственно любой класс MovieClip, TextField, ScrollPane предопределённый в AS 2.0 наследуют Object)
Здесь пишем

Код:

class Movement extends Object{

Цитата:

function Movement() {
}

Да, функция конструктор необязательна. Если ты вообще не планируешь использовать функцию конструктор, то не пиши её вовсе. У тебя будет просто класс со с татическими членами. Этот класс и его методы можно использовать глобально в любом объекте без объявления, как например класс Math. Функция конструктор нужна для создания независимого экземпляра класса. Ты можешь изменять переменные внутри экземпляров класса независимо друг от друга

Цитата:

static function moveBehindTheMouse(mc:MovieClip, dl:Number):Void {
mc.onEnterFrame = function() {
this._x += (_xmouse - mc._x) * dl;
this._y += (_ymouse - mc._y) * dl;
};
}

Если ты понимаешь разницу между статическими членами класса и не статическими - то это тебе решать когда какие использовать.

Название метода «moveBehindTheMouse» с точки зрения английского языка неверно.

Свойств _xmouse, _ymouse в классе Movement не существует.
Вот так написал бы я (может быть и иначе, но в контексте данной задачи):

Код:

import mx.utils.Delegate;

class Movement {



    private var target:MovieClip;

    private var dl:Number;



    public function Movement() {

        // пусто, инициализировать пока нечего

    }



    private function __followHandler():Void {

        var x:Number = this.target._x;

        var y:Number = this.target._y;

        var xmouse:Number = this.target._parent._xmouse;

        var ymouse:Number = this.target._parent._ymouse;

        x += (xmouse-x)/this.dl;

        y += (ymouse-y)/this.dl;

        this.target._x = x;

        this.target._y = y;

    }



    public function followTheMouse(mc:MovieClip, dl:Number):Void {

        this.target = mc;

        this.dl = dl;

        this.target.onEnterFrame = Delegate.create(this,this.__followHandler);

    }



    public function stopFollow():Void {

        delete this.target.onEnterFrame;

        delete this.target;

        delete this.dl;

    }

}

usage:

Код:

mover = new Moviement();

mover.followTheMouse(my_mc,3);

…

mover.stopFollow();

Подробнее расскажу позже, сейчас нужно бежать на работу.

з.Ы. miramax, любой класс является наследником Object, поэтому явно указывать на то, что это Object не нужно.

To __etc далеко не все компилляторы различных языков программирования вставляют за человека наследование по умолчанию (ситуация с метаклассами). То что в AS нужно писать extends Object это правило хорошего стиля, не меннее важное чем название класса с большой буквы.
To udaaff Если ты юзаешь this._x то тебе просто необходимо наследовать MovieClip и не пользоваться статическими переменными и функциями. Вообще инструкция this не работает внутри статической функции.
Так же в записи

Код:

 

class Movement extends Object{

   public static function f():void

   {

      trace(this._x)

   }

}

есть ещё одна ошибка, в классе Object свойство _x не определено. Необходимо наследовать MovieClip

Цитата:

Сообщение от miramax

To __etc далеко не все компилляторы различных языков программирования вставляют за человека наследование по умолчанию

Ок, предположим, первое — что любой класс не является Object, если он его не расширяет. Тогда чем он является? String? Или, быть может, Number?

Второе — в твоём случае нужно вызывать конструктор супер-класса. Однако никакого упоминания об этом я не вижу.

AS — язык объектный, любой класс является объектом и писать «extends Object» — масло масляное, не говоря уже о том, что сбивает с толку. Компилятор (точнее конвертер в байт-код) не добавляет никаких «extends Object» и правильно делает. Это скорее лишнее действие, которое абсолютно не нужно (не говоря уже о том, что это не правило хорошего стиля, а просто «памятка» автору, что каждый класс — объект), в отличие от именования классов с прописной буквы.

з.Ы. miramax, this внутри onEnterFrame ссылается на мувик, поэтому this там необходим, несмотря на то, что написано в стат. функции. С другой стороны, это является стилем AS1, но это уже другая история.