Форум Flasher.ru - switch не пашет

Форум Flasher.ru (http://www.flasher.ru/forum/index.php)

- ActionScript 3.0 (http://www.flasher.ru/forum/forumdisplay.php?f=83)

- - switch не пашет (http://www.flasher.ru/forum/showthread.php?t=195016)

switch не пашет

Бред какойто твориться, проверяю одну и туже пеерменную в свичи и через ИФ, в свиче не проходит, в ИФ проходит.
Как такое может быть?

Код AS3:

for (var i:int = w; i < w+size; i++)

                        {

                                for (var a:int = q; a < q+size; a++)

                                {

                                        //trace(map_unit_castl_arr[i][a]);

                                switch(map_unit_castl_arr[i][a])

                                        {

                                                case 0:

                                                        break;

                                                case 1:

                                                        break;

 

                                                case 2:

                                                        trace("444");

                                                        break;

                                                case 3:

                                                        break;

 

                                        }

                                        if(map_unit_castl_arr[i][a] == 2){trace("eee")}

 

 

                                }

 

                        }

trace("444"); и trace("eee"); должны отрабатывать обе или не одна! Отрабатывает только еее

А что будет, если сначала пробовать трейсить eee, а потом делать switch?

Что-то подсказывает мне, что в свиче директива break останавливает внутренний цикл.

Цитата:

Что-то подсказывает мне, что в свиче директива break останавливает внутренний цикл.

Как бы то ни было, тут есть еще одна проблема - в switch идет строгое сравнение, а == - это нестрогое. Показательный пример:

Код AS3:

package

{

    import flash.display.Sprite;

 

    public class Test extends Sprite

    {

 

        public function Test()

        {

            super();

 

            var a:Object = "1";

            var b:Object = 1;

 

            trace("a == b", (a == b));

            trace("a === b", (a === b));

 

            switch (a)

            {

                // в первую очередь сравниваем с числом и тут проверка не дает результата

                case 1:

                    trace("a is int");

                break;

 

                // а теперь сравниваем со строкой и проверка проходит

                case "1":

                    trace("a is string");

                break;

 

                default:

                    trace("a is something from another universe");

            }

 

        }

    }

}

Ну и, кстати, не выкидывает из цикла по break:

Код AS3:

package

{

    import flash.display.Sprite;

 

    public class Test extends Sprite

    {

 

        public function Test()

        {

            super();

 

            for(var i:int = 0; i < 2; i++)

            {

                switch (i)

                {

                    case 0:

                        trace("i == ", i);

                    break;

 

                    case 1:

                        trace("i == ", i);

                    break;

                }

            }

        }

    }

}

Цитата:

Сообщение от gloomyBrain (Сообщение 1122562)

А что будет, если сначала пробовать трейсить eee, а потом делать switch?

без разницы, отрабатывает и до и после свича.

Добавлено через 2 минуты
ДА! Ковычки решили проблему))) спс.

зы: А ИФу тоесть пофигу как сравнивать???

А switch это и есть ни что иное, как последовательность строгих if'ов. То есть

Код AS3:

switch(1)

{

case 1:

break;

 

case 2:

break;

 

}

Это абсолютно одно и то же, что и

Код AS3:

if (1 === 1)

{

}

else if (1 === 2)

{

}

if'у не "по фигу", он принимает в себя тот тип сравнения, который вы указываете. Указываете строгий === - получаете что число и строка это разные вещи, указываете нестрогий == - получаете что число и строка это одно и то же

Понятно тоесть в ифе "==" и "===" а в свиче наличие и отсутствие кавычек. Запомню)

На самом деле, при использовании элемента массива в операторе switch необходимо явно привести его к нужному типу (вместо swicth(arr[i]) - писать swicth(int(arr[i])) или какой там тип должен быть).