от 0 кадра

//---- добавляем кнопки к массиву --------

var buttonsArray:Array = [about_btn,portofolio_btn,contact_btn,new_btn];

 

//----цикл в массиве buttonsArray-----

//----установим некоторые свойства и добавим события кнопкам----

function setButtons():void {

 for (var i:int=0; i<buttonsArray.length; i++) {

  buttonsArray[i].id = i;

  buttonsArray[i].buttonMode = true;

  buttonsArray[i].mouseChildren = false;

  buttonsArray[i].mouseEnabled = true;

  buttonsArray[i].addEventListener(MouseEvent.ROLL_OVER,playOver);

  buttonsArray[i].addEventListener(MouseEvent.ROLL_OUT,playOut);

  buttonsArray[i].addEventListener(MouseEvent.CLICK,doClick);

 }

}

//----выполняется, когда мышь наводится над кнопкой----

function playOver(event:MouseEvent):void {

 event.currentTarget.gotoAndPlay("over");

}

//----выполняется, когда мышь уходит с кнопки----

function playOut(event:MouseEvent):void {

 event.currentTarget.gotoAndPlay("out");

}

//----выполняется, когда мышь кликает кнопку-----

function doClick(event:MouseEvent):void{

  //----установим переменную currentBtn равную----- 

//----идентификатору кнопки (id) , которая была кликнута-----

  var currentBtn:int = event.currentTarget.id;

  //----вызываем функцию setSelectedBtn

  setSelectedBtn(currentBtn);

}

/*проверим, какая кнопка была кликнута,

если id , переданная в функцию setSelectedBtn,

идентична id кликнутой кнопки 

мы полагаем, что кнопки находятся в положении нажатой down (выделенная)

и удаляем все события, добавленные к ней*/  

function setSelectedBtn(id:int):void{

 for (var i:int=0; i< buttonsArray.length; i++) {

  if (id == i) {

  buttonsArray[i].gotoAndStop("down");

  buttonsArray[i].buttonMode = false;

  buttonsArray[i].mouseEnabled = false;

  buttonsArray[i].removeEventListener(MouseEvent.ROLL_OVER,playOver);

  buttonsArray[i].removeEventListener(MouseEvent.ROLL_OUT,playOut);

  buttonsArray[i].removeEventListener(MouseEvent.CLICK,doClick);

  } else {

  if(buttonsArray[i].currentLabel =="down"){

  buttonsArray[i].gotoAndPlay("out");

  }

  buttonsArray[i].buttonMode = true;

  buttonsArray[i].mouseEnabled = true;

  buttonsArray[i].addEventListener(MouseEvent.ROLL_OVER,playOver);

  buttonsArray[i].addEventListener(MouseEvent.ROLL_OUT,playOut);

  buttonsArray[i].addEventListener(MouseEvent.CLICK,doClick);

  }

 }

}

//----вызываем функцию setButtons ----

setButtons();