package 

{

        import flash.display.Sprite;

        import flash.display.BlendMode;

        import flash.events.Event;

        import flash.display.StageAlign;

        import flash.display.StageScaleMode;

        import flash.events.MouseEvent;

        import flash.filters.DropShadowFilter;

        import flash.geom.Rectangle;

 

        public class Main extends Sprite 

        {

                private var _container       :Sprite = new Sprite();

                private var _mask            :Sprite = new Sprite();

                private var _background      :Sprite = new Sprite();

                private var _staticRectangle :Sprite = new Sprite();

                private var _dynamicRectangle:Sprite = new Sprite();

                private var _dragRect        :Rectangle = new Rectangle(0, 0, 0, 400);;

 

                public function Main():void 

                {

                        if (stage) init();

                        else addEventListener(Event.ADDED_TO_STAGE, init);

                }

 

                private function init(e:Event = null):void 

                {

                        removeEventListener(Event.ADDED_TO_STAGE, init);

                        stage.align = StageAlign.TOP_LEFT;

            stage.scaleMode = StageScaleMode.NO_SCALE;

 

                        // entry point

                        addChild(_container);

                        _container.x = _container.y = 50;

                        _background.graphics.beginFill(0x000000, 0.5);

                        _background.graphics.drawRect(0, 0, stage.stageWidth, stage.stageHeight);

                        _staticRectangle.graphics.beginFill(0x000000, 1);

                        _staticRectangle.graphics.drawRoundRect(0, 0, 500, 500, 12);

                        _mask.addChild(_staticRectangle);

                        _staticRectangle.x = 150;

                        _dynamicRectangle.graphics.beginFill(0x000000, 1);

                        _dynamicRectangle.graphics.drawRoundRect(0, 0, 200, 100, 12);

                        _mask.addChild(_dynamicRectangle);

                        _mask.graphics.beginFill(0x000000, 0);

                        _mask.graphics.drawRect(0, 0, stage.stageWidth, stage.stageHeight);

                        ////

                        _container.addChild(_background);

                        _container.addChild(_mask);

                        _mask.cacheAsBitmap = true;

                        _mask.blendMode = BlendMode.ALPHA;

                        _background.blendMode = BlendMode.NORMAL;

                        _container.blendMode = BlendMode.LAYER;

                        // цвет и соотношения прозрачностей заливки и бордера регулировать здесь - в настройках фильтра (дробные числа).

                        _container.filters = [new DropShadowFilter(0, 90, 0x000000, 0.10, 2, 2, 10.00, 3, false, true, true)];

 

                        _dynamicRectangle.addEventListener(MouseEvent.MOUSE_DOWN, onPress);

                }

                private function onPress(event:MouseEvent):void

                {

                        _dynamicRectangle.removeEventListener(MouseEvent.MOUSE_DOWN, onPress);

                        _dynamicRectangle.addEventListener(MouseEvent.MOUSE_UP, onUp);

                        _dynamicRectangle.startDrag(false, _dragRect);

                }

                private function onUp(event:MouseEvent):void

                {

                        _dynamicRectangle.removeEventListener(MouseEvent.MOUSE_UP, onUp);

                        _dynamicRectangle.addEventListener(MouseEvent.MOUSE_DOWN, onPress);

                        _dynamicRectangle.stopDrag();

                }

        }

 

}