Форум Flasher.ru

Форум Flasher.ru (http://www.flasher.ru/forum/index.php)
-   ActionScript 3.0 (http://www.flasher.ru/forum/forumdisplay.php?f=83)
-   -   Пауза при обработке нажатия клавиш (http://www.flasher.ru/forum/showthread.php?t=141305)

In8Finity 21.06.2010 19:10

Пауза при обработке нажатия клавиш
 
У меня есть объект на главной сцене, которым я планирую управлять клавишами.
Вот с помощью такой вот обычной конструкции:

Код AS3:

stage.addEventListener(KeyboardEvent.KEY_DOWN, onKeyPressed, false, 0, true);
.......
private function onKeyPressed(evt:KeyboardEvent):void {
        if ((evt.keyCode == 65) || (evt.keyCode == 37)) {// A or LEFT
                hero.x-=5;
        } else if ((evt.keyCode == 68) || (evt.keyCode == 39)) {// D or RIGHT
                    hero.x+=5;
        } else if (evt.keyCode == 32) {// SPACE
                hero.y-=5;
                }
        }

Проблема такая.
Когда я зажимаю, к примеру, клавишу "вправо" - герой сразу перемещается на 5 пикселей, потом пауза и потом движется дальше уже без пауз.
Вот как мне избавиться от этой паузы?
Есть какой-то секрет? Или это как-то по-другому реализуется?

kackbip 21.06.2010 19:19

По KeyboardEvent.KEY_DOWN нужно инициализировать движедние в таймере либо в EnterFrame. По KeyboardEvent.KEY_UP прекращать движение.

Вот по такому принципу можно сделать:

Код AS3:

var leftPressedFlag:Boolean=false;
var aPressedFlag:Boolean=false;
var rightPressedFlag:Boolean=false;
var dPressedFlag:Boolean=false;
 
stage.addEventListener(KeyboardEvent.KEY_DOWN, onKeyPressed, false, 0, true);
stage.addEventListener(KeyboardEvent.KEY_UP, onKeyReleased, false, 0, true);
 
function onKeyReleased(evt:KeyboardEvent):void{
        if(evt.keyCode == 37){//LEFT
                leftPressedFlag = false;
        }else if(evt.keyCode == 65){//A
        aPressedFlag = false;
        }else if(evt.keyCode == 39) {//RIGHT
                rightPressedFlag = false;
        } else if(evt.keyCode == 68){//D
                dPressedFlag = false;
        }
        if(!rightPressedFlag && !leftPressedFlag && !dPressedFlag && !aPressedFlag){
                stopMovingHero();
        }
}
 
function onKeyPressed(evt:KeyboardEvent):void {
        if(evt.keyCode == 37){//LEFT
                leftPressedFlag = true;
        }else if(evt.keyCode == 65){//A
        aPressedFlag = true;
        }else if(evt.keyCode == 39) {//RIGHT
                rightPressedFlag = true;
        } else if(evt.keyCode == 68){//D
                dPressedFlag = true;
        }
        if( (rightPressedFlag || leftPressedFlag || dPressedFlag || aPressedFlag) && !hasEventListener(Event.ENTER_FRAME)){
                startMovingHero();
        }
}
 
function startMovingHero():void{
        trace("startMovingHero");
        addEventListener(Event.ENTER_FRAME, moveHero);
}
function stopMovingHero():void{
        removeEventListener(Event.ENTER_FRAME, moveHero);
}
 
function moveHero(evt:Event):void{
        var speed:int = 0;
        if(leftPressedFlag || aPressedFlag){
                speed += -5;
        }
        if(rightPressedFlag || dPressedFlag){
                speed += 5;
        }
        hero.x += speed;
}


leofit 22.06.2010 11:37

а почему именно через down? сделайте изменение hero.x через KEY_UP

i.o. 22.06.2010 12:56

Цитата:

Сообщение от leofit (Сообщение 917128)
а почему именно через down? сделайте изменение hero.x через KEY_UP

В смысле движение будет, когда кнопка отжимается, а не нажимается? Как вы это себе представляете?))


Часовой пояс GMT +4, время: 09:24.

Copyright © 1999-2008 Flasher.ru. All rights reserved.
Работает на vBulletin®. Copyright ©2000 - 2026, Jelsoft Enterprises Ltd. Перевод: zCarot
Администрация сайта не несёт ответственности за любую предоставленную посетителями информацию. Подробнее см. Правила.