scrollBttn._visible = false;

// Set the scroll tween here

scrollTween = 3;

// Set the mousewheel scroll speed here

scrollSpeed = 10

//

// CASCADING STYLE SHEET

//

var styles = new TextField.StyleSheet();

// Set hyperlink colour and decoration here

styles.setStyle("a:link", {color:'#00FFFF', textDecoration:'none'});

styles.setStyle("a:hover", {color:'#00FFFF', textDecoration:'underline'});

txt_mc.txt.html = true;

txt_mc.txt.styleSheet = styles;

//

// WHEEL MOUSE LISTENER

//

var mouseListener:Object = new Object(this);

mouseListener.onMouseWheel = function(wheelNum:Number) {

        if (scrollBttn._y>=scrollBttn.originY) {

                scrollBttn._y -= (wheelNum/scrollRatio)*scrollSpeed;

                if (scrollBttn._y<scrollBttn.originY) {

                        scrollBttn._y = scrollBttn.originY;

                } else if (scrollBttn._y>scrollBttn.originY+scrollBar._height-scrollBttn._height) {

                        scrollBttn._y = scrollBttn.originY+scrollBar._height-scrollBttn._height;

                }

        }

        if (scrollBttn._y>scrollBttn.maxY) {

                scrollBttn._y = scrollBttn.maxY;

        }

};

Mouse.addListener(mouseListener);

//

// SCROLL BAR PRESS

//

scrollBar.onPress = function() {

        jumpTo = _ymouse-scrollBttn._height/2;

        if (jumpTo<0) {

                scrollBttn._y = 0;

        } else if (jumpTo>scrollBar._height-scrollBttn._height) {

                scrollBttn._y = scrollBar._height-scrollBttn._height;

        } else {

                scrollBttn._y = jumpTo;

        }

};

//

// SCROLL BAR SCRIPT

//

onEnterFrame = function () {

        scrollRatio = txt_mc._height/scrollBar._height;

        if (scrollRatio>1) {

                // Show scroll bar

                scrollBttn._visible = true;

                ratio = (txt_mc._height-scrollBar._height)/(scrollBar._height-scrollBttn._height);

                destScroll = ((-scrollBttn._y+txt_mc.originY)*ratio)+txt_mc.originY;

                txt_mc._y += Math.ceil((destScroll-txt_mc._y)/scrollTween);

        } else {

                // Hide scroll bar

                scrollBttn._visible = false;

        }

        txt_mc.txt._height = txt_mc.txt.textHeight+10;

};

//

// POSITION CONTENT BASED ON WINDOW DIMENSIONS

//

setContents = function () {

        // Align bg

        _parent.bg_mc.bg._width = contentWidth;

        _parent.bg_mc.bg._height = contentHeight;

        _parent.bg_mc.bg._x = -contentWidth/2;

        _parent.bg_mc.bg._y = -((contentHeight)/2);

        this._x = (_parent.bg_mc._x-contentWidth/2)+contentBorder;

        this._y = (_parent.bg_mc._y-contentHeight/2)+contentBorder+30;

        txt_mc.txt._width = (contentWidth-contentBorder*2)-scrollBar._width-10;

        // Align scrollbar

        scrollBar._x = (contentWidth-contentBorder*2-scrollBar._width);

        scrollBar._height = (contentHeight-contentBorder*2)-30;

        scrollBttn._x = scrollBar._x;

        scrollBttn.originY = scrollBttn._y;

        scrollBttn.originX = scrollBttn._x;

        scrollBttn.maxY = scrollBar._height-scrollBttn._height+scrollBttn.originY-1;

        txt_mc.originY = txt_mc._y;

        // Align mask

        mask_mc._width = contentWidth-contentBorder*2;

        mask_mc._height = scrollBar._height;

};

//

// LOAD XML

//

loadXML = function (loaded) {

        if (loaded) {

                xmlNode = this.firstChild;

                contentBorder = Number(xmlNode.childNodes[0].attributes.Border);

                contentWidth = Number(xmlNode.childNodes[0].attributes.Width);

                contentHeight = Number(xmlNode.childNodes[0].attributes.Height);

                txt_mc.txt.htmlText = xmlNode.childNodes[0].firstChild.nodeValue;

                headerName.text = xmlNode.attributes.Name;

                setContents();

        } else {

                trace("Error loading XML");

        }

};

xmlData = new XML();

xmlData.ignoreWhite = true;

xmlData.onLoad = loadXML;

// Load default XML if no XML defined in index.xml

if (_root.toLoad == undefined) {

        _root.toLoad = "content/yasamal.xml";

}

xmlData.load(_root.toLoad);