Форум Flasher.ru - как подписать в качестве хендлера события функцию другого объекта?

Форум Flasher.ru (http://www.flasher.ru/forum/index.php)

- ActionScript 3.0 (http://www.flasher.ru/forum/forumdisplay.php?f=83)

как подписать в качестве хендлера события функцию другого объекта?

subj

Здесь (http://flasher.ru/forum/showthread.php?t=79873) понятно написано как это делать в одном классе.

А как правильно указать то, что обработчик является методом другого класса?
Так или нет?
addEventListener(MouseEvent.CLICK, экземлярДругогоКласса.handler);

И есть ли возможность отлова события в каких либо объектах не подписанных на обработку.
Предположим у меня есть некоторый объект, кот. посылает некое событие и неизвестно существует ли он на данный момент или нет. И есть некоторые объекты, кот. должны обработать это событие, если оно вдруг произойдет, но они не знают создан ли объект или нет, да и не надо им это знать.

Как правильно реализовать такое?

Спасибо.

так низя делать. обработчики должны быть приватными.

1. Можно подписать любой обработчик из области видимости:

Код:

addEventListener(MouseEvent.CLICK, экземлярДругогоКласса.handler);

addEventListener(MouseEvent.CLICK, trace);

addEventListener(MouseEvent.CLICK, MyClass.myStaticFunction);

2. Или юзать третий объект, который существует всегда и знает когда существует нужный объект, или заюзать что-то кроме обсервера.

Единственное требование, handler должен иметь 1ым аргументом Event, или что нибудь что пройдет как Event (* или Object)

Лучше см. пост #2.

Если listener сделать публичным.
Main.as3:

Код:

package {

        import flash.display.Sprite;

        import foo.Foo;

        import bar.Bar;

        import flash.events.MouseEvent;

        

        public class Main extends Sprite

        {

                public function Main()

                {

                        var f:Foo = new Foo();

                        var b:Bar = new Bar();

                        

                        f.addEventListener(MouseEvent.CLICK, b.mouseClickListener);

                        

                        addChild(f);

                        addChild(b);                        

                }

        }

}

Foo.as3:

Код:

package foo

{

        import flash.display.Sprite;

        import flash.text.TextField;

        

        public class Foo extends Sprite

        {

                public function Foo()

                {

                        x = 50;

                        y = 50;

                        

                        graphics.beginFill(0x009900);

                        graphics.drawCircle(0, 0, 10);

                        

                        var text:TextField = new TextField();

                        text.text = "Foo";

                        text.x = 10;

                        text.y = 10;

                        

                        addChild(text);

                        

                }

        }

}

Bar.as3:

Код:

package bar

{

        import flash.display.Sprite;

        import flash.events.MouseEvent;

        import flash.text.TextField;

        

        public class Bar extends Sprite

        {

                public function Bar()

                {

                        x = 100;

                        y = 100;

                        

                        graphics.beginFill(0x990000);

                        graphics.drawCircle(0, 0, 10);

                        

                        var text:TextField = new TextField();

                        text.text = "Bar";

                        text.x = 10;

                        text.y = 10;

                        

                        addChild(text);

                }

                

                public function mouseClickListener(e:MouseEvent):void

                {

                        trace("Вызван Bar.mouseClickListener()");

                }

        }

}

Если listener сделать приватным, код чуть-чуть поменяется:
В Main.as3:

Код:

package {

        import flash.display.Sprite;

        import foo.Foo;

        import bar.Bar;

        import flash.events.MouseEvent;

        

        public class Main extends Sprite

        {

                protected var bClickListener:Function;

                

                public function Main()

                {

                        var f:Foo = new Foo();

                        var b:Bar = new Bar();

                        

                        bClickListener = function(e:MouseEvent):void {

                                trace("MAIN: Foo CLICKED");

                                b.getClickListener(e)();

                        };

                        

                        f.addEventListener(MouseEvent.CLICK, bClickListener);

                        

                        addChild(f);

                        addChild(b);                        

                }

        }

}

В Bar.as3 - mouseClickListener делается приватным, и добавляется public метод.

Код:

public function getClickListener(e:MouseEvent):Function

{

        return function():void {

                mouseClickListener(e);

        };

}

Всё можно сделать красивее, расширив например класс Function через prototype, добавив в него функцию типа Delegate.
Код только для примера, набросал не для реального применения.

Плохой пример.

Я бы делал так:

Код:

public class ClassWithEvents {

  public var clickFunction:Function = null;

  

  public function ClassWithEvents() {

    this.addEventListener(MouseEvent.CLICK,myClickFunction);

  }



  private function myClickFunction(event:MouseEvent) {

    if (clickFunction != null)

      clickFunction(event);

  }

}

Или если позволяет структура програмы то так:

Код:

public class ClassWithEvents {

  public function ClassWithEvents(clickFunction:Function) {

    this.addEventListener(MouseEvent.CLICK,clickFunction);

  }

}

Соответственно использовать первый вариант можно так:

Код:

var a:ClassWithEvents = new ClassWithEvents();

a.clickFunction = somePrivateFunction;

И второй вариант:

Код:

var a:ClassWithEvents = new ClassWithEvents(somePrivateFunction);

А можно просто напросто заюзать event dispatcher =)