Форум Flasher.ru - Реализация onReleaseOutside

Форум Flasher.ru (http://www.flasher.ru/forum/index.php)

- ActionScript 3.0 (http://www.flasher.ru/forum/forumdisplay.php?f=83)

- - Реализация onReleaseOutside (http://www.flasher.ru/forum/showthread.php?t=86312)

Реализация onReleaseOutside

Собственно меня интересует ответ на сабж, как сделать это событие в AS3. Если кто-то уже поднимал этот вопрос киньте ссылку, по поиску ничего не нашел.

onReleaseOutside() EventHandler
----
flash.display.InteractiveObject dispatches event: mouseUp
----
Replaced in the new event model by a mouseUp event after a call to flash.display.InteractiveObject.setCapture().
----
Topic: ActionScript 2.0 Migration.

InteractiveObject.setCapture убрали.
Можно так:

Код:

package {

        import flash.display.Sprite;

        import flash.events.*;



        dynamic public class Test extends Sprite {



                function Test() {

                        buttonMode=true;

                        addEventListener(MouseEvent.MOUSE_DOWN, onMouseDown);

                }

                

                private function onMouseDown(e:Event):void {

                        stage.addEventListener(MouseEvent.MOUSE_UP, onMouseUp);

                }

                private function onMouseUp(e:Event):void {

                        stage.removeEventListener(MouseEvent.MOUSE_UP, onMouseUp);

                        if (e.target==this) {

                                trace("onRelease");

                        } else {

                                trace("onReleaseOutside");

                        }

                }

                

        }

}

может я что-то не догоняю, но что это за flash.display.InteractiveObject и как его использовать?

Это базовый класс для DisplayObjectContaiener который в свою очередь базовый для Sprite. ну а Sprite базовый для MovieClip

MerlinTwi, это в хелпе Flex 2 8)

MerlinTwi попробовал не работает, то есть когда за пределами клипа не срабатывает событие, хотя вроде должно.

__etc, старый хелп, пора обновить :)
см. livedocs.macromedia.com коммент от Jul 25, 2006 at 6:49 PM

UPD
Работает со stage. В общем со stage фактически как использовать parent, то есть не совсем хороший способ

То если есть вложенность и когда я нажимаю на объект, срабатывает 2 события MOUSE_DOWN и что тогда?

NewMan_by, не понял, как 2 события MOUSE_DOWN ?

MerlinTwi,

на случай если над stage есть объекты с MOUSE_UP, которые будут перекрывать MOUSE_UP сцены
cчитаю нужным немного добавить:

Код:

package {

import flash.display.Sprite;

import flash.events.*;



dynamic public class Test extends Sprite {



        function Test() {

                buttonMode=true;

                addEventListener(MouseEvent.MOUSE_DOWN, onMouseDown);

        }

                

        private function onMouseDown(e:Event):void {

                stage.addEventListener(MouseEvent.MOUSE_UP, onMouseUp, true);

        }

        private function onMouseUp(e:Event):void {

                stage.removeEventListener(MouseEvent.MOUSE_UP, onMouseUp, true);

                if (e.target==this) {

                        trace("onRelease");

                } else {

                        trace("onReleaseOutside");

                }

        }

                

}

}

еще могут быть запарки с утягиванием мышки со сцены - тогда листнер onMouseUp не будет удалён и сработает при следующем поднимании мышки над сценой... так что надо повесить на stage листнер для ещё одного события

artcraft, вроде бы MOUSE_UP срабатывает, если отпускать кнопку мыши за пределами флешки.

вроде должен, но у меня в FF не всегда

точнее, если утянуть мышку за пределы браузера и только там поднять кнопку

artcraft, у меня за пределами браузера тоже срабатывает. Не срабатывает, только если удерживая кнопку мыши переключить фокус на другое приложение.
Кстати, если ловить mouseUp на стадии capture, то событие не срабатывает, если отпускать мышку на пустом месте stage, где нет никаких объектов.

В результате: если добавить проверку на потерю фокуса и необязательно чтобы у кнопки стояло buttonMode=true, то проверка будет выглядеть так:

Код:

package {

        import flash.display.Sprite;

        import flash.events.*;



        dynamic public class Test extends Sprite {

                private var checkMouseUp:Boolean;



                function Test() {

                        addEventListener(MouseEvent.MOUSE_DOWN, mouseDown);

                        addEventListener(Event.DEACTIVATE, onDeactivate);

                }

                

                private function mouseDown(e:Event):void {

                        stage.addEventListener(MouseEvent.MOUSE_UP, mouseUp);

                        checkMouseUp=true;

                }

                

                private function onDeactivate(e:Event):void {

                        if (checkMouseUp) mouseUp(null);

                }

                

                private function mouseUp(e:Event):void {

                        checkMouseUp=false;

                        stage.removeEventListener(MouseEvent.MOUSE_UP, mouseUp);

                        if (e && (e.target==this || contains(e.target))) {

                                trace("onRelease");

                        } else {

                                trace("onReleaseOutside");

                        }

                }

                

        }

}

P.S. Вот и нафига, спрашивается, надо было им убирать событие ReleaseOutside?

Цитата:

Сообщение от MerlinTwi

P.S. Вот и нафига, спрашивается, надо было им убирать событие ReleaseOutside?

Они просто как и мы не знали как это лучше сделать :)

Кстати, еще стоит учесть, что в методе mouseUp объект может быть уже удален с timeline и stage==null. Поэтому ссылку на stage стоит запомнить в методе mouseDown.

В дополнение нашего обсуждения, полезный совет от senocular
81. Глобальные события