Форум Flasher.ru - сохранение на жесткий из проекта

Форум Flasher.ru (http://www.flasher.ru/forum/index.php)

- ActionScript 1.0/2.0 (http://www.flasher.ru/forum/forumdisplay.php?f=93)

- - сохранение на жесткий из проекта (http://www.flasher.ru/forum/showthread.php?t=66733)

сохранение на жесткий из проекта

Видел в какой-то галерее кнопочку, сохранить картинку... Галерея флюшевая. Отсюда вопрос - как реализовать фичу с jpg и можно ли тем же способом сохранять к себе из проекта pdf doc и прочих зверюшек?

Если через сервер - то без проблем. getURL, кажется. Просто открывай документ отдельно.

Нет не с сервера.
Покопался по форумам нашел тему - через Zinc, SWF2kit и проч. Юзаю Цинк. Нашел функцию mdm.copyfile - все торчком. Вот только копирует он в строго заданную папку :/ а мне бы чтобы юзер браузнул сам куда ему картинку качать. Никто не в курсе?

От Роста -
var fileRef = new flash.net.FileReference();
fileRef.browse();
Будет катить в 8ке.......

спасибо,
скоро ждать 8-ки? )).

зы. от роста (это что?)

Уже вышла бета версия. Но как уже говорил, требуется время на то чтобы плеер начал активно использоваться. Что толку от того что ты сделал флеш самыми новыми фичами, когда ее могут посмотреть единицы?

От Роста - это значит Ростислава (Флеш-потрошитель)

Только текст:
function saveText(){
userText.data.Doc = textWindow;
}
function loadText(){
textWindow = userText.data.Doc;
}
userText = SharedObject.getLocal("userText");

Цитата:

Сообщение от mr<Xepypr>

Только текст:
function saveText(){
userText.data.Doc = textWindow;
}
function loadText(){
textWindow = userText.data.Doc;
}
userText = SharedObject.getLocal("userText");

Это ты к чему ?

MDM Support ответил следующим образом:
hi PYatka,

welcome to the boards!

it's quite complex task you want to do,
it take me some time to make fully fledged code for all of us wanting to do similiar thing,
I've attached files so you can compile them and simply start testing,
follow code comments to learn how it works:

Код:

//

mdminit();

//

import mx.controls.Button;

/**

simply one button makes

entire GUI

*/

var browseBtn:Button;

/**

variables used later in code

to remember:

- last folder selected by user

- last file name selected (entered) by user

- last extension of last file name

*/

var lastSelectedFolder:String = null;

var lastSelectedFile:String = null;

var lastUsedExtension:String = null;

/**

button click handler

*/

function clickHandler(evt:Object):Void {

if (evt.target != browseBtn) {

 return;

}

browseBtn.enabled = false;

selectFileToCopy();

}

/**

that funciton open browse dialog

allowing user to select file to copy

(target file path is returned to callback function)

*/

function selectFileToCopy(userNotCancelled:String):Void {

if (userNotCancelled == "false") {

 return;

}

var folder = getLastSelectedFolder();

var title = "Select file to copy";

var filterList = "jpeg doc pdfs|*.jpg;*.doc;*.pdf";

var filterText = "File types";

var buttonText = "Select";

mdm.browsefiledir(folder);

mdm.browsefiletitle(title);

mdm.browsefile_filterlist(filterList);

mdm.browsefile_filtertext(filterText);

mdm.browsefile_buttontext(buttonText);

mdm.browsefile(sourceFileSelected);

//

browseBtn.enabled = true;

}

/**

callback function for selectFileToCopy

check what user entered simpy by checking

if file exists

*/

function sourceFileSelected(filePath:String):Void {

if (filePath == "" || filePath == "false") {

 return;

}

lastSelectedFile = getFileName(filePath);

lastSelectedFolder = getFolderName(filePath);

//

mdm.fileexists(filePath, checkFilePathBeforeProceeding);

}

/**

that callback function checks if selected file

exists on machine - user can enter some non-existing

file names in dialog

*/

function checkFilePathBeforeProceeding(exists:String):Void {

if (exists == "false") {

 lastSelectedFile = null;

 var promptText = "please select existing file!!!";

 var promptType = "okcancel";

 var promptStyle = "alert";

 mdm.prompt_modal(promptText, promptType, promptStyle, selectFileToCopy);

 return;

}

selectPathWhereToCopy();

}

/**

that function open browse dialog (SAVE AS)

allowing user to select path where

file should be copied (user can enter new name)

*/

function selectPathWhereToCopy(userNotCancelled:String):Void {

if (userNotCancelled == "false") {

 return;

}

var folder = getLastSelectedFolder();

var title = "Select new location (Save As) for "+getLastSelectedFile();

var defaultFileName:String = getLastSelectedFile();

var currentExtension:String = getFileExtension(getLastSelectedFile());

switch (currentExtension) {

case ".doc" :

 lastUsedExtension = ".doc";

 var filterList = "word files|*.doc";

 break;

case ".jpg" :

 lastUsedExtension = ".jpg";

 var filterList = "jpeg files|*.jpg";

 break;

case ".pdf" :

 lastUsedExtension = ".pdf";

 var filterList = "Acrobat files|*.pdf";

 break;

}

var filterText = "File types";

var buttonText = "Save";

mdm.browsefiledir(folder);

mdm.browsefiletitle(title);

mdm.browsefile_filterlist(filterList);

mdm.browsefile_filtertext(filterText);

mdm.browsefile_buttontext(buttonText);

mdm.browsefile_def(defaultFileName, targetPathSelected);

}

/**

that callback function checks what is returned

from browse dialog to select target file

not allowed: spaces in names,

names consisting only with extensions

overriding existing file if target path == source path

*/

function targetPathSelected(filePath:String):Void {

if (filePath == "" || filePath == "false") {

 return;

}

var targetFolder:String = getFolderName(filePath);

var targetFile:String = getFileName(filePath);

var targetFileExtension:String = getFileExtension(targetFile);

var hasSpaces:Boolean = (targetFile.indexOf(" ") != -1);

var nameEqualsExtension:Boolean = (targetFile == getLastUsedExtension());

var hasValidExtension:Boolean = (targetFileExtension == getLastUsedExtension());

// # 1 no spaces

if (hasSpaces == true) {

 var promptText = "no spaces allowed in file name";

 var promptType = "okcancel";

 var promptStyle = "alert";

 mdm.prompt_modal(promptText, promptType, promptStyle, selectPathWhereToCopy);

 return;

}

// # 2 name should have at least one character not only extension

if (nameEqualsExtension == true) {

 var promptText = "file name should have at least one character";

 var promptType = "okcancel";

 var promptStyle = "alert";

 mdm.prompt_modal(promptText, promptType, promptStyle, selectPathWhereToCopy);

 return;

}

// # 3 automatically add correct extension if missed

if (hasValidExtension == false) {

 targetFile = targetFile+getLastUsedExtension();

}

// #4 don't copy if target==source

var sourcePath:String = getLastSelectedFolder()+getLastSelectedFile();

var targetPath:String = targetFolder+targetFile;

var isToOverride:Boolean = (sourcePath == targetPath);

if (isToOverride == true) {

 var promptText = "file cannot override itself - choose another location!";

 var promptType = "okcancel";

 var promptStyle = "alert";

 mdm.prompt_modal(promptText, promptType, promptStyle, selectPathWhereToCopy);

 return;

}

// GO copy file

lastSelectedFolder = targetFolder;

mdm.copyfile(sourcePath, targetPath);

}

/**

return last selected folder

*/

function getLastSelectedFolder():String {

if (lastSelectedFolder == null) {

 return _level0.mdm_desktop;

}

return lastSelectedFolder;

}

/**

here is a couple of helper functions

used accros a code

*/

/**

return last selected file

*/

function getLastSelectedFile():String {

return lastSelectedFile;

}

/**

return file name from file path

*/

function getFileName(fullPath:String):String {

var sep:String = _level0.mdm_appdir.substr(-1);

return fullPath.substr(fullPath.lastIndexOf(sep)+1);

}

/**

return folder name from file path

*/

function getFolderName(fullPath:String):String {

var sep:String = _level0.mdm_appdir.substr(-1);

return fullPath.substr(0, fullPath.lastIndexOf(sep)+1);

}

/**

return extension from fileName

*/

function getFileExtension(fileName:String):String {

return fileName.substr(fileName.lastIndexOf("."));

}

/**

return last extension used in filter

*/

function getLastUsedExtension():String {

return lastUsedExtension;

}

/**

simply resize button when needed

*/

function onResize():Void {

browseBtn.move(10, 10);

browseBtn.setSize(Stage.width-20, Stage.height-20);

}

//

// go baby

//

Stage.scaleMode = "noScale";

Stage.align = "TL";

Stage.addListener(this);

//

browseBtn.label = "Click to choose an file";

browseBtn.move(10, 10);

browseBtn.setSize(Stage.width-20, Stage.height-20);

browseBtn.addEventListener("click", clickHandler);

enjoy

hth,
regards,
peter

Цитата:

Сообщение от iNils

Спасибо.
Тогда вопрос такой.
SWFKit и ZINC будут понимать синтаксис 8ки?

Цитата:

Сообщение от Fl00r

Спасибо.
Тогда вопрос такой.
SWFKit и ZINC будут понимать синтаксис 8ки?

Кто их знает? :) Текущие версии врядли, а вот после следующие со временем да.

:/ придется пользовать mdm.sintax... ой как лень - длинючий... за то рабочий )

да может после выхода восьмёрки потребность в подобного рода программах отпадёт...

Цитата:

Сообщение от kuzen

да может после выхода восьмёрки потребность в подобного рода программах отпадёт...

тогда макромедию (адоб) обвинят в монопольной политике и разделят на две разные компании :))

Ну. Поглазев на возможности MDM ... врядли.
Их язык полностью компенсирует недостатки Флэша для работы как с полноценным приложением. Я был приятно, често говоря, удивлен, почитав Manual к нему.
Хотя, если Флэш сподобиться к такому небезопасному шагу, то мне так будет проще. AS легче и компактнее чем mdm.script

Цитата:

Сообщение от Fl00r

AS легче и компактнее чем mdm.script

Не фига не проще ... просто уже привыкли

Все же врядли это будет. Наверняка у них есть негласный договор и прочее, каждый берет свой кусок пирога и другие не трогает. Ведь сколько лет и версий люди делают и флеша сринсейверы сторонними продуктами, а Макромедиа так и не поставила данную возможность во флеш и более того, не выпустила отдельный софт для для создания этого. Зато всякие RoboDemo, Max и прочее выпускает.