Форум Flasher.ru

Форум Flasher.ru (http://www.flasher.ru/forum/index.php)
-   ActionScript 3.0 (http://www.flasher.ru/forum/forumdisplay.php?f=83)
-   -   Обращение к неопределённому методу в ссылке на подгружаемый swf (http://www.flasher.ru/forum/showthread.php?t=183495)

tsarapkabel 23.08.2012 15:00
Обращение к неопределённому методу в ссылке на подгружаемый swf
 
Loader'ом подгружается swf. В swf есть публичный метод: setLoc(xPos:int, yPos:int).

Можно обратиться к этому методу сразу:
Код AS3:
LoaderInfo.content.setLoc(12, 34);
Однако, сохраняя ссылку на swf как Sprite:
Код AS3:
var spr:Sprite = new Sprite();

spr = LoaderInfo.content;
теряется возможность обращаться к публичному методу
Код AS3:
spr.setLoc(0, 0);
ибо метод сей в Спрайте не определён.

Как быть в таком случае? Как получить ссылку на подгружаемую swf и иметь возможность обращаться к её публичным методам через эту ссылку?

Wolsh 23.08.2012 15:07
Интерфейс.

tsarapkabel 23.08.2012 15:40
Спасибо. Немного подробнее?

Создаю интерфейс:
Код AS3:
package {

        public interface ISetLoc {

                function setLoc(xPos:uint, yPos:uint):void;

        }

}
Создаю ссылку на swf:
Код AS3:
var isetloc:ISetLoc;

isetloc = LoaderInfo.content as ISetLoc;

trace(isetloc);        // null, далее ни addChild, ни setLoc
Добавлено через 1 час 7 минут
Пока решил проблему так:
Код AS3:
var linkToSwf:* = Loader.content;

this.addChild(linkToSwf);

linkToSwf.setLoc(0, 0);
Интересно узнать, есть ли более правильные способы.

Wolsh 23.08.2012 17:25
Есть. Интерфейс.
Код AS3:
import ISetLoc;

// переменная для использования как реализации интерфейса

var linkToSwf:ISetLoc = Loader.content as ISetLoc;

linkToSwf.setLoc(0, 0);

// а для работы как с дисплейным объектом приводим к дисплейному типу (Спрайт, Мувиклип если надо)

var swfClip:DisplayObject = Loader.content as DisplayObject;

this.addChild(swfClip);

illuzor 23.08.2012 18:25
tsarapkabel, http://blog.illuzor.com/2012/08/06/a...asses_methods/

tsarapkabel 23.08.2012 18:54
Цитата:
Сообщение от Wolsh (Сообщение 1093510)
Есть. Интерфейс.
Как DO всё работает, нет проблем, а вот как ISetLoc linkToSwf.setLoc(0, 0) отказывается, сославшись на null.

Цитата:
Сообщение от illuzor (Сообщение 1093531)
...
Спасибо, читаю!

fish_r 23.08.2012 19:02
Есть ещё способ. Сделать swc с классами из swf-шки, но без вкомиливания в проект ( в фд "External library" ), типы будут объявлены в основной флешке, но сами классы станут доступными только после загрузки swf. После загрузки уже привести объект к нужному типу.

Wolsh 23.08.2012 19:05
Цитата:
отказывается, сославшись на null.
Не понял. Так а Мейн подгружаемой-то реализует ISetLoc? Не было никогда проблем с этим. Проверьте детали. Документ-класс подгружаемой implements ISetLoc. Обязательно.

caseyryan 23.08.2012 19:29
Если подгружаемая SWF имеет другой ApplicationDomain то интерфейс не прокатит, пока приложение не будет загружено в тот же домен
Но что-то мне подсказывает, что Wolsh прав на счет применения интерфейса в документ классе

tsarapkabel 23.08.2012 20:05
Цитата:
Сообщение от Wolsh (Сообщение 1093539)
Мейн подгружаемой-то реализует ISetLoc?
Теперь ясно. :) Нет, не реализует. В данном случае хотел узнать способ обращения без изменения кода подгружаемой флешки.

Wolsh 23.08.2012 20:18
Цитата:
Если подгружаемая SWF имеет другой ApplicationDomain то интерфейс не прокатит, пока приложение не будет загружено в тот же домен
Смелое утверждение.
IPlugin.as :
Код AS3:
package  

{

        public interface IPlugin 

        {

                function setPosition(x:Number, y:Number):void;

        }

}
Main2.as >> Plugin.swf DocumentClass :
Код AS3:
package  

{

        import flash.display.Sprite;

 

        public class Main2 extends Sprite implements IPlugin 

        {

                public function Main2() { }

 

                /* INTERFACE IPlugin */

                public function setPosition(x:Number, y:Number):void 

                {

                        trace("x: ", x, ",  y: ", y);

                }

        }

}
Main.as :
Код AS3:
package 

{

        import flash.display.Loader;

        import flash.display.Sprite;

        import flash.events.Event;

        import flash.net.URLRequest;

        import IPlugin;

 

        public class Main extends Sprite 

        {

                public function Main():void 

                {

                        if (stage) init();

                        else addEventListener(Event.ADDED_TO_STAGE, init);

                }

 

                private function init(e:Event = null):void 

                {

                        removeEventListener(Event.ADDED_TO_STAGE, init);

                        // entry point

                        var swfloader:Loader = new Loader();

                        swfloader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);

                        swfloader.load(new URLRequest("Plugin.swf"));

                }

 

                private function completeHandler(event:Event):void 

                {

                        var plugin:IPlugin = event.target.loader.content as IPlugin;

                        trace("Plugin: ", plugin);

                        plugin.setPosition(10, 15);

                        trace(this.loaderInfo.applicationDomain == event.target.loader.content.loaderInfo.applicationDomain); /// output: false

                }

        }

}

gloomyBrain 24.08.2012 00:56
На сколько я помню, приведение к интерфейсу не сработает, если SecurityDomain'ы разные. Именно security, не application.
Что до ApplicationDomain'ов, то там вообще все не очень прозрачно.

caseyryan 24.08.2012 09:31
Похоже здесь ближе всех к истине оказался gloomyBrain, но речь о песочнице
applicationDomain для этого тоже нужен.
Вот, нашел реальный пример из одного своего приложения:
Код AS3:
if (Security.sandboxType == Security.REMOTE) {

        var context:LoaderContext = new LoaderContext();

        context.applicationDomain = new ApplicationDomain(ApplicationDomain.currentDomain);

        loader.loadBytes(byteArray, context);

}
Если грузить без контекста, и потом проверить интерфейсы загруженной флешки, то, несмотря на то, что интерфейс прменяется тот же, такой код:
Код AS3:
trace(loadedItem is IControllable); // выдаст false
с контекстом, выдаст true

Wolsh 24.08.2012 11:21
Но если обе флэшки лежат на одном домене — проблем нет.
Файлы те же, только код обработчика поменял на вывод в текстфилд
Код AS3:
private function completeHandler(event:Event):void 

{

        var plugin:IPlugin = event.target.loader.content as IPlugin;

 

        var txt:TextField = new TextField();

        addChild(txt);

        txt.x = 100, txt.y = 100;

        txt.width = 500;

        txt.height = 500;

        txt.text = (plugin != null) ? " IPlugin" : " null";

        txt.appendText("\n Security sandbox is REMOTE: " + (Security.sandboxType == Security.REMOTE).toString());

        txt.appendText("\n Plugin: " + (plugin as Object).toString());

        txt.appendText("\n Plugin is IPlugin: " + (plugin is IPlugin).toString());

        txt.appendText("\n applicationDomain равны? : " + (this.loaderInfo.applicationDomain == event.target.loader.content.loaderInfo.applicationDomain).toString());

        plugin.setPosition(10, 15);

}


Часовой пояс GMT +4, время: 16:21.

Copyright © 1999-2008 Flasher.ru. All rights reserved.
Работает на vBulletin®. Copyright ©2000 - 2026, Jelsoft Enterprises Ltd. Перевод: zCarot
Администрация сайта не несёт ответственности за любую предоставленную посетителями информацию. Подробнее см. Правила.